kde-frameworks/purpose: 5.76.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/kde-frameworks/purpose/Manifest b/kde-frameworks/purpose/Manifest
new file mode 100644
index 0000000000..90985ad4c9
--- /dev/null
+++ b/kde-frameworks/purpose/Manifest
@@ -0,0 +1 @@
+DIST purpose-5.76.0.tar.xz 157920 BLAKE2B 38e55b8b4137c82b3d36d5ffd2a9519e98df66e226ad0d23f20e1f67c7b1973769bf28cfdd2d39cfec1a23a98844d19a5dac247413afdb2a8a88d76e1bfdfd35 SHA512 9d73b299894ee6fbaca73740c0901955d040ff867cacd0c18f3808f6437d5898a5a501e5a07205ea6a1608e32be7a0b910990fe9d5b693ae610bbbbbecb90d40
diff --git a/kde-frameworks/purpose/purpose-5.76.0.ebuild b/kde-frameworks/purpose/purpose-5.76.0.ebuild
new file mode 100644
index 0000000000..6e6ea9578b
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.76.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.1
+inherit ecm kde.org optfeature xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="bluetooth +dolphin +kaccounts"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	dolphin? ( =kde-frameworks/knotifications-${PVCUT}*:5 )
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-19.04.3:5
+		net-libs/accounts-qt
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${PVCUT}:5
+	bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
+	kaccounts? ( net-libs/accounts-qml )
+"
+
+# requires running environment
+RESTRICT+=" test"
+
+src_prepare() {
+	ecm_src_prepare
+	cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package dolphin KF5Notifications)
+		$(cmake_use_find_package kaccounts KAccounts)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Optional dependencies:"
+		optfeature "Send through KDE Connect" kde-misc/kdeconnect
+	fi
+	ecm_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}