kde-frameworks/purpose: 5.72.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/kde-frameworks/purpose/Manifest b/kde-frameworks/purpose/Manifest
new file mode 100644
index 0000000000..1fed14cea1
--- /dev/null
+++ b/kde-frameworks/purpose/Manifest
@@ -0,0 +1 @@
+DIST purpose-5.72.0.tar.xz 155416 BLAKE2B 01559b33bf8d3a303766b805872d4ad84db4eb9e6c6ad0fd766f491167318d5826f09a29eca852ee162a24798f7f8aec55d3a825b32a2521719c4ba75d0d2352 SHA512 64359268f82d35e0c4a79f9a3b3472ea06217b719f73f145263598fe8f4df3e0025bcec4baf28a3dd5a7f86e2bb9ed1f2f46027a12c1c55235de349e22cd1284
diff --git a/kde-frameworks/purpose/purpose-5.72.0.ebuild b/kde-frameworks/purpose/purpose-5.72.0.ebuild
new file mode 100644
index 0000000000..53c1c4293f
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.72.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+dolphin +kaccounts"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	dolphin? ( =kde-frameworks/knotifications-${PVCUT}*:5 )
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-19.04.3:5
+		net-libs/accounts-qt
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${PVCUT}:5
+	kaccounts? ( net-libs/accounts-qml )
+"
+
+# requires running environment
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package dolphin KF5Notifications)
+		$(cmake_use_find_package kaccounts KAccounts)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst(){
+	ecm_pkg_postinst
+
+	if ! has_version "kde-misc/kdeconnect[app]" ; then
+		elog "Optional runtime dependency:"
+		elog "kde-misc/kdeconnect[app] (send through KDE Connect)"
+	fi
+}