kde-frameworks/purpose: 5.74.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/kde-frameworks/purpose/Manifest b/kde-frameworks/purpose/Manifest
new file mode 100644
index 0000000000..086a0ce567
--- /dev/null
+++ b/kde-frameworks/purpose/Manifest
@@ -0,0 +1 @@
+DIST purpose-5.74.0.tar.xz 156216 BLAKE2B 7d810f2d3b1af7cd041b8e9449fc5934bca7b739b5edf7fe1f5da553f264f189cfac0dd715dddf66a6f46be0a9389dae5d9eb35558b0c41b89dd36e53d945ccd SHA512 dea52fd5d10cc0c34ecab742b691675076ddf1346e2b352cd5f74cd266576f85eb9d721bf68a29cea62f9879b826bf375b70580451c31bdd33509f57ae3cf23a
diff --git a/kde-frameworks/purpose/purpose-5.74.0.ebuild b/kde-frameworks/purpose/purpose-5.74.0.ebuild
new file mode 100644
index 0000000000..564e82df53
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.74.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.14.2
+inherit ecm kde.org xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="bluetooth +dolphin +kaccounts"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	dolphin? ( =kde-frameworks/knotifications-${PVCUT}*:5 )
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-19.04.3:5
+		net-libs/accounts-qt
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${PVCUT}:5
+	bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
+	kaccounts? ( net-libs/accounts-qml )
+"
+
+# requires running environment
+RESTRICT+=" test"
+
+src_prepare() {
+	ecm_src_prepare
+	cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package dolphin KF5Notifications)
+		$(cmake_use_find_package kaccounts KAccounts)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	xdg_icon_cache_update
+
+	if ! has_version "kde-misc/kdeconnect[app]" ; then
+		elog "Optional runtime dependency:"
+		elog "kde-misc/kdeconnect[app] (send through KDE Connect)"
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}