kde-frameworks/purpose: 5.85.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/kde-frameworks/purpose/Manifest b/kde-frameworks/purpose/Manifest
new file mode 100644
index 0000000000..7a0e4e2bc3
--- /dev/null
+++ b/kde-frameworks/purpose/Manifest
@@ -0,0 +1 @@
+DIST purpose-5.85.0.tar.xz 161412 BLAKE2B c6d55396ebde4f8b3f08a71c429bce4f0bbfe1303907d06faf841ab53147a78b582bd63e4b731eb6c5d16b939dade6dab2ca30930a9fa31babb9c1b68c37e53e SHA512 30da8286d7eb8b0652656d0c52fe0f95dd4c3c1f86e468af5f9b546b0afc996dbf9f3a0e011376de5b58e34bf529faca9f3add7ee0e820ab693745c98e21b1ed
diff --git a/kde-frameworks/purpose/purpose-5.85.0.ebuild b/kde-frameworks/purpose/purpose-5.85.0.ebuild
new file mode 100644
index 0000000000..0dc933045f
--- /dev/null
+++ b/kde-frameworks/purpose/purpose-5.85.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_QTHELP="false"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.2
+inherit ecm kde.org optfeature xdg-utils
+
+DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="bluetooth +kaccounts"
+
+# requires running environment
+RESTRICT+=" test"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kirigami-${PVCUT}*:5
+	=kde-frameworks/knotifications-${PVCUT}*:5
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-19.04.3:5
+		net-libs/accounts-qt
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${PVCUT}:5
+	bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
+	kaccounts? ( net-libs/accounts-qml )
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	use bluetooth ||
+		cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kaccounts KAccounts)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Send through KDE Connect" kde-misc/kdeconnect
+	fi
+	ecm_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}