kde-plasma/kscreenlocker: 5.21.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 95 insertions, 0 deletions

diff --git a/kde-plasma/kscreenlocker/Manifest b/kde-plasma/kscreenlocker/Manifest
index d8c3ca7547..9b78c30c1f 100644
--- a/kde-plasma/kscreenlocker/Manifest
+++ b/kde-plasma/kscreenlocker/Manifest
@@ -1 +1,2 @@
 DIST kscreenlocker-5.20.90.tar.xz 117272 BLAKE2B e1061c5b07c6eafad6867ea470ff65b3e4afc50402c9fe510b42a5a33da1cf59ec612a05fb679b52dba83b16e8181b4bfad25ce823440d963323227fc1c1c14c SHA512 be176a5f34bf2a0d82a604937354680cb2c04e5d7f21d88c5db2e19e4069d7a83bea5fdbd55c9fd0bb2636086d8ce348f0641c034f8b052ebbb3a210e9a137cb
+DIST kscreenlocker-5.21.0.tar.xz 117280 BLAKE2B 181ee14ded67b828627d0ca608245ff9ef4f45ba924d7b10737264aec4c9cca859f15a47aa96fdebb2b93eebc97a71d44a5309fb73b6f4c4269072759ccbbfc5 SHA512 c429f20b6fb6e5e3209c22a15d18d0e4c8a34e5ee9c58d8bb9077c19ecc8e5d0d7d57ceabad0a16858f25add7bef9ca8f9b62c69a5eaa01e8f7e6086d95e9f08
diff --git a/kde-plasma/kscreenlocker/kscreenlocker-5.21.0.ebuild b/kde-plasma/kscreenlocker/kscreenlocker-5.21.0.ebuild
new file mode 100644
index 0000000000..b1c7212ccf
--- /dev/null
+++ b/kde-plasma/kscreenlocker/kscreenlocker-5.21.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="forceoptional"
+KFMIN=5.78.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org pam
+
+DESCRIPTION="Library and components for secure lock screen architecture"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+pam"
+
+RESTRICT+=" test"
+
+COMMON_DEPEND="
+	dev-libs/wayland
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+	pam? ( sys-libs/pam )
+"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+PDEPEND="
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+	use test || cmake_run_in greeter cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPAM_REQUIRED=$(usex pam)
+		$(cmake_use_find_package pam PAM)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# requires running environment
+	local myctestargs=(
+		-E x11LockerTest
+	)
+	ecm_src_test
+}
+
+src_install() {
+	ecm_src_install
+
+	if use pam; then
+		newpamd "${FILESDIR}/kde.pam" kde
+		newpamd "${FILESDIR}/kde-np.pam" kde-np
+	else
+		chown root "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+		chmod +s "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
+	fi
+}