kde-plasma/ksysguard: 5.19.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 60 insertions, 0 deletions

diff --git a/kde-plasma/ksysguard/Manifest b/kde-plasma/ksysguard/Manifest
new file mode 100644
index 0000000000..f9cf844f98
--- /dev/null
+++ b/kde-plasma/ksysguard/Manifest
@@ -0,0 +1 @@
+DIST ksysguard-5.19.90.tar.xz 563636 BLAKE2B 3ae2d63b9cde216f60f3b8b55e7d2e7945d09be7666133e049dde68ea9e2f7e99654be01ff395b3b035eba63198d9f211d4ed9d9f8717f0edc4c0405b463a0e7 SHA512 4630674aa21f18d3c42cc0e1be86cb258eaf697e26cfeadfc72c414c3b8983b6de8c8ecda7093ae397005560b853afa511a9a26c60ec42c653353d0516612f85
diff --git a/kde-plasma/ksysguard/ksysguard-5.19.90.ebuild b/kde-plasma/ksysguard/ksysguard-5.19.90.ebuild
new file mode 100644
index 0000000000..7704d799b0
--- /dev/null
+++ b/kde-plasma/ksysguard/ksysguard-5.19.90.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.74.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.0
+inherit ecm kde.org
+
+DESCRIPTION="Network-enabled task manager and system monitor"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="lm-sensors +network networkmanager"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kinit-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-plasma/libksysguard-${PVCUT}:5
+	lm-sensors? ( sys-apps/lm-sensors:= )
+	network? (
+		dev-libs/libnl:3
+		net-libs/libpcap
+		sys-libs/libcap
+	)
+	networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package lm-sensors Sensors)
+		$(cmake_use_find_package networkmanager KF5NetworkManagerQt)
+		$(cmake_use_find_package network libpcap)
+		$(cmake_use_find_package network NL)
+	)
+
+	ecm_src_configure
+}