media-sound/elisa: 22.04.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/media-sound/elisa/Manifest b/media-sound/elisa/Manifest
new file mode 100644
index 0000000000..34860e7abc
--- /dev/null
+++ b/media-sound/elisa/Manifest
@@ -0,0 +1 @@
+DIST elisa-22.04.1.tar.xz 1747180 BLAKE2B 9d74ab4346126e615809dbddb81c9d69601674e3dac7fbd7cb5d53fa77b4577ad5182984189e1a7eb452474c24b4add6f71f47d807c681f994835c7ecef53ef2 SHA512 f31bd4540bc224bdb0225735d359e6415be5f5ec094a32c29120fd81bfbf1a887d22c3857635bb4bc709b130ca934756ea14d9bcfb63f01777118a84f5016a43
diff --git a/media-sound/elisa/elisa-22.04.1.ebuild b/media-sound/elisa/elisa-22.04.1.ebuild
new file mode 100644
index 0000000000..418ca8f7c2
--- /dev/null
+++ b/media-sound/elisa/elisa-22.04.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KDE_GEAR="true"
+KFMIN=5.92.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Simple music player by KDE"
+HOMEPAGE="https://elisa.kde.org/ https://apps.kde.org/elisa/"
+
+LICENSE="LGPL-3+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="mpris semantic-desktop +vlc"
+
+RESTRICT="test"
+
+BDEPEND="sys-devel/gettext"
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	mpris? (
+		>=dev-qt/qtdbus-${QTMIN}:5
+		>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	)
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	vlc? ( media-video/vlc:= )
+	!vlc? ( >=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package mpris KF5DBusAddons)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package vlc LIBVLC)
+	)
+
+	ecm_src_configure
+}