media-sound/elisa: 22.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/media-sound/elisa/Manifest b/media-sound/elisa/Manifest
new file mode 100644
index 0000000000..8947e3cd98
--- /dev/null
+++ b/media-sound/elisa/Manifest
@@ -0,0 +1 @@
+DIST elisa-22.04.3.tar.xz 1747400 BLAKE2B c4f3a91f1f32e8735221961291c9a1fe998dadd648bced18f8f7c8e03f973397feda9d9d143901f26f28eb3e808468f1c780e646343858706be30609521f47e8 SHA512 ac1ba9b06eb263f409e798001093cb0ca0b56df565a38a69c78f61bd8820bdd0f3aa53510a0ef0efcab56bea001798ef4c028d48f425499942369e5d5b718040
diff --git a/media-sound/elisa/elisa-22.04.3.ebuild b/media-sound/elisa/elisa-22.04.3.ebuild
new file mode 100644
index 0000000000..66a84037f9
--- /dev/null
+++ b/media-sound/elisa/elisa-22.04.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KDE_GEAR="true"
+KFMIN=5.92.0
+QTMIN=5.15.4
+inherit ecm kde.org
+
+DESCRIPTION="Simple music player by KDE"
+HOMEPAGE="https://elisa.kde.org/ https://apps.kde.org/elisa/"
+
+LICENSE="LGPL-3+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="mpris semantic-desktop +vlc"
+
+RESTRICT="test"
+
+BDEPEND="sys-devel/gettext"
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	mpris? (
+		>=dev-qt/qtdbus-${QTMIN}:5
+		>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	)
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	vlc? ( media-video/vlc:= )
+	!vlc? ( >=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package mpris KF5DBusAddons)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package vlc LIBVLC)
+	)
+
+	ecm_src_configure
+}