[net-libs/telepathy-qt4] Add live ebuild, to get KDE telepathy 9999 working again

(Portage version: 2.2.0_alpha79/git/Linux i686, unsigned Manifest commit)

2 files changed, 67 insertions, 0 deletions

diff --git a/net-libs/telepathy-qt4/metadata.xml b/net-libs/telepathy-qt4/metadata.xml
new file mode 100644
index 0000000000..25afcbce2d
--- /dev/null
+++ b/net-libs/telepathy-qt4/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>qt</herd>
+	<use>
+		<flag name='glib'>Enable support for various telepathy/glib related packages</flag>
+		<flag name='farsight'>Enable support for farsight connection manager</flag>
+	</use>
+</pkgmetadata>
diff --git a/net-libs/telepathy-qt4/telepathy-qt4-9999.ebuild b/net-libs/telepathy-qt4/telepathy-qt4-9999.ebuild
new file mode 100644
index 0000000000..8c49e86303
--- /dev/null
+++ b/net-libs/telepathy-qt4/telepathy-qt4-9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-qt4/telepathy-qt4-0.8.0.ebuild,v 1.1 2011/12/03 19:26:48 pesa Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="2:2.5"
+EGIT_REPO_URI="git://anongit.freedesktop.org/telepathy/telepathy-qt4"
+
+inherit python base cmake-utils git-2
+
+DESCRIPTION="Qt4 bindings for the Telepathy D-Bus protocol"
+HOMEPAGE="http://telepathy.freedesktop.org/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug farsight glib"
+
+RDEPEND="
+	dev-python/dbus-python
+	>=x11-libs/qt-core-4.6.0:4[glib?]
+	>=x11-libs/qt-dbus-4.6.0:4
+	farsight? (
+		dev-libs/dbus-glib
+		dev-libs/libxml2
+		media-libs/gstreamer
+		net-libs/telepathy-farsight
+		>=net-libs/telepathy-glib-0.15.1
+	)
+	glib? ( dev-libs/glib:2 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	dev-util/pkgconfig
+"
+
+DOCS=( AUTHORS ChangeLog HACKING NEWS README )
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	base_src_prepare
+
+	sed -i -e '/^add_subdirectory(examples)$/d' CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable debug DEBUG_OUTPUT)
+		$(cmake-utils_use_with glib)
+		$(cmake-utils_use_with farsight)
+	)
+	cmake-utils_src_configure
+}