blob: 55899f045be1046c26ca278b042978135cba52d0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="forceoptional"
ECM_TEST="true"
KFMIN=5.66.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.12.3
VIRTUALX_REQUIRED="test"
inherit ecm kde.org
DESCRIPTION="KDE Plasma desktop"
# Avoid pulling in xf86-input-{evdev,libinput,synaptics} DEPENDs
# just for 1 header each. touchpad also uses a header from xorg-server.
SHA_EVDEV="425ed601"
SHA_LIBINPUT="e52daf20"
SHA_SYNAPTICS="383355fa"
SHA_XSERVER="d511a301"
XORG_URI="https://gitlab.freedesktop.org/xorg/driver/PKG/-/raw"
SRC_URI+="
${XORG_URI/PKG/xf86-input-evdev}/${SHA_EVDEV}/include/evdev-properties.h -> evdev-properties.h-${SHA_EVDEV}
${XORG_URI/PKG/xf86-input-libinput}/${SHA_LIBINPUT}/include/libinput-properties.h -> libinput-properties.h-${SHA_LIBINPUT}
${XORG_URI/PKG/xf86-input-synaptics}/${SHA_SYNAPTICS}/include/synaptics-properties.h -> synaptics-properties.h-${SHA_SYNAPTICS}
${XORG_URI/driver\/PKG/xserver}/${SHA_XSERVER}/include/xserver-properties.h -> xserver-properties.h-${SHA_XSERVER}
"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="~amd64"
IUSE="emoji +fontconfig ibus scim +semantic-desktop"
COMMON_DEPEND="
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtx11extras-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/attica-${KFMIN}:5
>=kde-frameworks/kactivities-${KFMIN}:5
>=kde-frameworks/kactivities-stats-${KFMIN}:5
>=kde-frameworks/karchive-${KFMIN}:5
>=kde-frameworks/kauth-${KFMIN}:5
>=kde-frameworks/kbookmarks-${KFMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kcodecs-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/kdeclarative-${KFMIN}:5
>=kde-frameworks/kded-${KFMIN}:5
>=kde-frameworks/kdelibs4support-${KFMIN}:5
>=kde-frameworks/kemoticons-${KFMIN}:5
>=kde-frameworks/kglobalaccel-${KFMIN}:5
>=kde-frameworks/kguiaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemmodels-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/krunner-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwallet-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/plasma-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=kde-frameworks/sonnet-${KFMIN}:5
|| (
>=kde-plasma/kwin-${PVCUT}:5
>=gui-wm/kwinft-$(ver_cut 1-2):5
)
>=kde-plasma/libksysguard-${PVCUT}:5
>=kde-plasma/plasma-workspace-${PVCUT}:5
media-libs/phonon[qt5(+)]
x11-libs/libX11
x11-libs/libXcursor
x11-libs/libXfixes
x11-libs/libXi
x11-libs/libxcb[xkb]
x11-libs/libxkbfile
emoji? (
app-i18n/ibus[emoji]
dev-libs/glib:2
media-fonts/noto-emoji
)
fontconfig? (
media-libs/fontconfig
media-libs/freetype
x11-libs/libXft
x11-libs/xcb-util-image
)
ibus? (
app-i18n/ibus[emoji?]
dev-libs/glib:2
>=dev-qt/qtx11extras-${QTMIN}:5
x11-libs/libxcb
x11-libs/xcb-util-keysyms
)
scim? ( app-i18n/scim )
semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
"
DEPEND="${COMMON_DEPEND}
dev-libs/boost
x11-base/xorg-proto
fontconfig? ( x11-libs/libXrender )
"
RDEPEND="${COMMON_DEPEND}
>=dev-qt/qtgraphicaleffects-${QTMIN}:5
>=dev-qt/qtquickcontrols2-${QTMIN}:5
>=kde-frameworks/kirigami-${KFMIN}:5
>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
>=kde-plasma/breeze-${PVCUT}:5
>=kde-plasma/kde-cli-tools-${PVCUT}:5
>=kde-plasma/oxygen-${PVCUT}:5
sys-apps/util-linux
x11-apps/setxkbmap
!<kde-plasma/kdeplasma-addons-5.15.80
"
PATCHES=(
"${FILESDIR}/${P}-override-include-dirs.patch" # downstream patch
"${FILESDIR}/${P}-synaptics-header.patch" # in Plasma/5.19
)
src_unpack() {
kde.org_src_unpack
mkdir "${WORKDIR}/include" || die "Failed to prepare evdev/libinput dir"
cp "${DISTDIR}"/evdev-properties.h-${SHA_EVDEV} \
"${WORKDIR}"/include/evdev-properties.h || die "Failed to copy evdev"
cp "${DISTDIR}"/libinput-properties.h-${SHA_LIBINPUT} \
"${WORKDIR}"/include/libinput-properties.h || die "Failed to copy libinput"
cp "${DISTDIR}"/synaptics-properties.h-${SHA_SYNAPTICS} \
"${WORKDIR}"/include/synaptics-properties.h || die "Failed to copy synaptics"
cp "${DISTDIR}"/xserver-properties.h-${SHA_XSERVER} \
"${WORKDIR}"/include/xserver-properties.h || die "Failed to copy xserver"
}
src_prepare() {
ecm_src_prepare
if ! use ibus; then
sed -e "s/Qt5X11Extras_FOUND AND XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package fontconfig Fontconfig)
-DEvdev_INCLUDE_DIRS="${WORKDIR}"/include
-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}"/include
-DSynaptics_INCLUDE_DIRS="${WORKDIR}"/include
$(cmake_use_find_package scim SCIM)
$(cmake_use_find_package semantic-desktop KF5Baloo)
)
if ! use emoji && ! use ibus; then
mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_IBus=ON )
fi
ecm_src_configure
}
src_test() {
# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
# needs D-Bus, bug #634166
local myctestargs=(
-j1
-E "(foldermodeltest|positionertest|test_kio_fonts)"
)
ecm_src_test
}
|
GitWeb