1 files changed, 51 insertions, 0 deletions
diff --git a/sys-libs/libomp/libomp-3.9.1.ebuild b/sys-libs/libomp/libomp-3.9.1.ebuild
new file mode 100644
index 00000000..db4d6231
--- /dev/null
+++ b/sys-libs/libomp/libomp-3.9.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+
+inherit cmake-multilib
+
+MY_P=openmp-${PV}
+DESCRIPTION="OpenMP runtime library for LLVM/clang compiler"
+HOMEPAGE="http://openmp.llvm.org"
+SRC_URI="http://llvm.org/releases/${PV}/${MY_P}.src.tar.xz"
+
+# Additional licenses:
+# - MIT-licensed Intel code,
+# - LLVM Software Grant from Intel.
+
+LICENSE="|| ( UoI-NCSA MIT ) MIT LLVM-Grant"
+SLOT="0/3.9"
+KEYWORDS="~amd64 ~x86"
+IUSE="hwloc ompt"
+
+RDEPEND="hwloc? ( sys-apps/hwloc:0=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	dev-lang/perl"
+
+S="${WORKDIR}/${MY_P}.src"
+
+PATCHES=(
+	# backport of https://reviews.llvm.org/D24563
+	"${FILESDIR}"/${PN}-3.9.0-optional-aliases.patch
+	# backport of https://reviews.llvm.org/D25071
+	"${FILESDIR}"/${PN}-3.9.0-musl-strerror_r.patch
+	"${FILESDIR}"/${PN}-3.9.0-use-va_copy-macro.patch
+)
+
+multilib_src_configure() {
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIBOMP_LIBDIR_SUFFIX="${libdir#lib}"
+		-DLIBOMP_USE_HWLOC=$(usex hwloc)
+		-DLIBOMP_OMPT_SUPPORT=$(usex ompt)
+		# do not install libgomp.so & libiomp5.so aliases
+		-DLIBOMP_INSTALL_ALIASES=OFF
+		# disable unnecessary hack copying stuff back to srcdir
+		-DLIBOMP_COPY_EXPORTS=OFF
+	)
+	cmake-utils_src_configure
+}