dev-qt/*: add version 6.4.0

Also restore USE="xml" where still missing.

Bug: https://bugs.gentoo.org/838970
Bug: https://bugs.gentoo.org/872026
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

35 files changed, 814 insertions, 2 deletions

diff --git a/dev-qt/qt5compat/Manifest b/dev-qt/qt5compat/Manifest
new file mode 100644
index 00000000..105809d9
--- /dev/null
+++ b/dev-qt/qt5compat/Manifest
@@ -0,0 +1 @@
+DIST qt5compat-everywhere-src-6.4.0.tar.xz 14641720 BLAKE2B abed031d736e2f05856a02e96251bf77c12823866c722247360a19d592a71e52a2fb5bac121baa91dd264806fff6b2230d41ab92346ee92c4fcef7607838d4a0 SHA512 d14ebf4ed6061b7154fdd67ac71849bcfb109c9911dcc9279c01bf07b6f58cf26a882f16be6228040e6465345259a16be2296481c2129c88710fa7b4da747ba5
diff --git a/dev-qt/qt5compat/qt5compat-6.4.0.ebuild b/dev-qt/qt5compat/qt5compat-6.4.0.ebuild
new file mode 100644
index 00000000..2bf0684e
--- /dev/null
+++ b/dev-qt/qt5compat/qt5compat-6.4.0.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt module containing the unsupported Qt 5 APIs"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui,network]
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtbase/Manifest b/dev-qt/qtbase/Manifest
new file mode 100644
index 00000000..c57d973a
--- /dev/null
+++ b/dev-qt/qtbase/Manifest
@@ -0,0 +1 @@
+DIST qtbase-everywhere-src-6.4.0.tar.xz 47957680 BLAKE2B 488843aa5a7373a517aa993c4fd9ddf6b9926941ee1af2e337cea3dee035cf3bf237aa040705328d2b33e1c60d1cdbe72844621f8f2f79259e53a4a28f6c6267 SHA512 7c9430da115529fa5697d134bf53d185259de23529d6db17398d91d48a0b7a95acd1fbe55189a2d2b3a2ecdafb27065ea99f29f7022110c95a45d6c04ebf46a3
diff --git a/dev-qt/qtbase/qtbase-6.4.0.ebuild b/dev-qt/qtbase/qtbase-6.4.0.ebuild
new file mode 100644
index 00000000..39f291d5
--- /dev/null
+++ b/dev-qt/qtbase/qtbase-6.4.0.ebuild
@@ -0,0 +1,178 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Cross-platform application development framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+# Qt Modules
+IUSE="+concurrent +dbus +gui +network +sql opengl +widgets +xml zstd"
+REQUIRED_USE="
+	opengl? ( gui )
+	widgets? ( gui )
+	X? ( || ( evdev libinput ) )
+"
+
+QTGUI_IUSE="accessibility egl eglfs evdev gles2-only +jpeg +libinput tslib tuio vulkan +X"
+QTNETWORK_IUSE="brotli gssapi libproxy sctp +ssl vnc"
+QTSQL_IUSE="freetds mysql oci8 odbc postgres +sqlite"
+IUSE+=" ${QTGUI_IUSE} ${QTNETWORK_IUSE} ${QTSQL_IUSE} cups gtk icu systemd +udev"
+# QtPrintSupport = QtGui + QtWidgets enabled.
+# ibus = xkbcommon + dbus, and xkbcommon needs either libinput or X
+REQUIRED_USE+="
+	$(printf '%s? ( gui ) ' ${QTGUI_IUSE//+/})
+	$(printf '%s? ( network ) ' ${QTNETWORK_IUSE//+/})
+	$(printf '%s? ( sql ) ' ${QTSQL_IUSE//+/})
+	accessibility? ( dbus X )
+	cups? ( gui widgets )
+	eglfs? ( egl )
+	gtk? ( widgets )
+	gui? ( || ( eglfs X ) || ( libinput X ) )
+	libinput? ( udev )
+	sql? ( || ( freetds mysql oci8 odbc postgres sqlite ) )
+	vnc? ( gui )
+	X? ( gles2-only? ( egl ) )
+"
+
+# TODO:
+# qtimageformats: mng not done yet, qtimageformats.git upstream commit 9443239c
+# qtnetwork: connman, networkmanager
+DEPEND="
+	app-crypt/libb2
+	dev-libs/double-conversion:=
+	dev-libs/glib:2
+	dev-libs/libpcre2:=[pcre16,unicode]
+	dev-util/gtk-update-icon-cache
+	media-libs/fontconfig
+	>=media-libs/freetype-2.6.1:2
+	>=media-libs/harfbuzz-1.6.0:=
+	media-libs/tiff:0
+	>=sys-apps/dbus-1.4.20
+	sys-libs/zlib:=
+	brotli? ( app-arch/brotli:= )
+	evdev? ( sys-libs/mtdev )
+	freetds? ( dev-db/freetds )
+	gles2-only? ( media-libs/libglvnd )
+	!gles2-only? ( media-libs/libglvnd[X] )
+	gssapi? ( virtual/krb5 )
+	gtk? (
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+	gui? ( media-libs/libpng:0= )
+	icu? ( dev-libs/icu:= )
+	!icu? ( virtual/libiconv )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	libinput? (
+		dev-libs/libinput:=
+		>=x11-libs/libxkbcommon-0.5.0
+	)
+	libproxy? ( net-libs/libproxy )
+	mysql? ( dev-db/mysql-connector-c:= )
+	oci8? ( dev-db/oracle-instantclient:=[sdk] )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( dev-db/postgresql:* )
+	sctp? ( kernel_linux? ( net-misc/lksctp-tools ) )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? ( dev-libs/openssl:= )
+	systemd? ( sys-apps/systemd:= )
+	tslib? ( >=x11-libs/tslib-1.21 )
+	udev? ( virtual/libudev:= )
+	vulkan? ( dev-util/vulkan-headers )
+	X? (
+		x11-libs/libdrm
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		>=x11-libs/libxcb-1.12:=[xkb]
+		>=x11-libs/libxkbcommon-0.5.0[X]
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-keysyms
+		x11-libs/xcb-util-renderutil
+		x11-libs/xcb-util-wm
+	)
+	zstd? ( app-arch/zstd:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_BINDIR=${QT6_BINDIR}
+		-DINSTALL_INCLUDEDIR=${QT6_HEADERDIR}
+		-DINSTALL_LIBDIR=${QT6_LIBDIR}
+		-DINSTALL_ARCHDATADIR=${QT6_ARCHDATADIR}
+		-DINSTALL_PLUGINSDIR=${QT6_PLUGINDIR}
+		-DINSTALL_LIBEXECDIR=${QT6_LIBEXECDIR}
+		-DINSTALL_QMLDIR=${QT6_QMLDIR}
+		-DINSTALL_DATADIR=${QT6_DATADIR}
+		-DINSTALL_DOCDIR=${QT6_DOCDIR}
+		-DINSTALL_TRANSLATIONSDIR=${QT6_TRANSLATIONDIR}
+		-DINSTALL_SYSCONFDIR=${QT6_SYSCONFDIR}
+		-DINSTALL_MKSPECSDIR=${QT6_ARCHDATADIR}/mkspecs
+		-DINSTALL_EXAMPLESDIR=${QT6_EXAMPLESDIR}
+		-DQT_FEATURE_androiddeployqt=OFF
+		$(qt_feature concurrent)
+		$(qt_feature dbus)
+		$(qt_feature gui)
+		$(qt_feature gui testlib)
+		$(qt_feature icu)
+		$(qt_feature network)
+		$(qt_feature sql)
+		$(qt_feature systemd journald)
+		$(qt_feature udev libudev)
+		$(qt_feature xml)
+		$(qt_feature zstd)
+	)
+	use gui && mycmakeargs+=(
+		$(qt_feature accessibility accessibility_atspi_bridge)
+		$(qt_feature egl)
+		$(qt_feature eglfs eglfs_egldevice)
+		$(qt_feature eglfs eglfs_gbm)
+		$(qt_feature evdev)
+		$(qt_feature evdev mtdev)
+		-DQT_FEATURE_gif=ON
+		$(qt_feature jpeg)
+		$(qt_feature opengl)
+		$(qt_feature gles2-only opengles2)
+		$(qt_feature libinput)
+		$(qt_feature tslib)
+		$(qt_feature tuio tuiotouch)
+		$(qt_feature vulkan)
+		$(qt_feature widgets)
+		$(qt_feature X xcb)
+		$(qt_feature X xcb_xlib)
+	)
+	use widgets && mycmakeargs+=(
+		$(qt_feature cups)
+		$(qt_feature gtk gtk3)
+	)
+	if use libinput || use X; then
+		mycmakeargs+=( -DQT_FEATURE_xkbcommon=ON )
+	fi
+	use network && mycmakeargs+=(
+		$(qt_feature brotli)
+		$(qt_feature gssapi)
+		$(qt_feature libproxy)
+		$(qt_feature sctp)
+		$(qt_feature ssl openssl)
+		$(qt_feature vnc)
+	)
+	use sql && mycmakeargs+=(
+		$(qt_feature freetds sql_tds)
+		$(qt_feature mysql sql_mysql)
+		$(qt_feature oci8 sql_oci)
+		$(qt_feature odbc sql_odbc)
+		$(qt_feature postgres sql_psql)
+		$(qt_feature sqlite sql_sqlite)
+		$(qt_feature sqlite system_sqlite)
+	)
+
+	qt6-build_src_configure
+}
diff --git a/dev-qt/qtbase/qtbase-6.4.9999.ebuild b/dev-qt/qtbase/qtbase-6.4.9999.ebuild
index 36931e0e..39f291d5 100644
--- a/dev-qt/qtbase/qtbase-6.4.9999.ebuild
+++ b/dev-qt/qtbase/qtbase-6.4.9999.ebuild
@@ -12,8 +12,7 @@ if [[ ${QT6_BUILD_TYPE} == release ]]; then
 fi
 
 # Qt Modules
-# TODO: Restore/patch xml flag support (seems fixed in 6.9999).
-IUSE="+concurrent +dbus +gui +network +sql opengl +widgets zstd"
+IUSE="+concurrent +dbus +gui +network +sql opengl +widgets +xml zstd"
 REQUIRED_USE="
 	opengl? ( gui )
 	widgets? ( gui )
@@ -128,6 +127,7 @@ src_configure() {
 		$(qt_feature sql)
 		$(qt_feature systemd journald)
 		$(qt_feature udev libudev)
+		$(qt_feature xml)
 		$(qt_feature zstd)
 	)
 	use gui && mycmakeargs+=(
diff --git a/dev-qt/qtdeclarative/Manifest b/dev-qt/qtdeclarative/Manifest
new file mode 100644
index 00000000..8faf4b19
--- /dev/null
+++ b/dev-qt/qtdeclarative/Manifest
@@ -0,0 +1 @@
+DIST qtdeclarative-everywhere-src-6.4.0.tar.xz 30538764 BLAKE2B 919081ba8a29a07daa01084388454a3d5f814e12ff5d1a4d3b647650e4bd6a839876baee1ab09e664e55e814338dbf675e70e4c44c28842a363c8f2dcf1a2b18 SHA512 6d43c09a14e2ca236fc50166ed477e37084e89a67a04d914f30f31662a18a4e6d0433cb9b2f0654ba9ffcbcd7abcb5dadcb7b12f0ef5928fc11b10925ee6f41e
diff --git a/dev-qt/qtdeclarative/qtdeclarative-6.4.0.ebuild b/dev-qt/qtdeclarative/qtdeclarative-6.4.0.ebuild
new file mode 100644
index 00000000..e8ac7edd
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-6.4.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Declarative (Quick 2)"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="opengl +sql +widgets"
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network,opengl=,sql=,widgets=]
+	=dev-qt/qtshadertools-${PV}*
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(qt_feature opengl)
+		$(qt_feature sql)
+		$(qt_feature widgets)
+	)
+
+	qt6-build_src_configure
+}
diff --git a/dev-qt/qtimageformats/Manifest b/dev-qt/qtimageformats/Manifest
new file mode 100644
index 00000000..57479559
--- /dev/null
+++ b/dev-qt/qtimageformats/Manifest
@@ -0,0 +1 @@
+DIST qtimageformats-everywhere-src-6.4.0.tar.xz 1861400 BLAKE2B be2d99999a29b5876981d0768d63dab6a70181a1643be73e83cb7bf6771bd35462165e1a848206d4f69018c3388118f4bd94a336ff28ab19dbc75973eb86463b SHA512 3a7302cfbe9187ffb753c7171c62bbf43223c9c876bb0df20de8b593d51ef775bffeff124d269ed8d4ce7e1fb3d55790acd75bce0b5d5bfa223e5e83dfb41f01
diff --git a/dev-qt/qtimageformats/qtimageformats-6.4.0.ebuild b/dev-qt/qtimageformats/qtimageformats-6.4.0.ebuild
new file mode 100644
index 00000000..f1a8354e
--- /dev/null
+++ b/dev-qt/qtimageformats/qtimageformats-6.4.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Additional format plugins for the Qt image I/O system"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="mng"
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui]
+	media-libs/libwebp:=
+	media-libs/tiff
+	mng? ( media-libs/libmng:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DQT_FEATURE_jasper=OFF
+		$(qt_feature mng)
+		-DQT_FEATURE_tiff=ON
+		-DQT_FEATURE_webp=ON
+		-DQT_FEATURE_system-tiff=ON
+		-DQT_FEATURE_system-webp=ON
+	)
+
+	qt6-build_src_configure
+}
diff --git a/dev-qt/qtmultimedia/Manifest b/dev-qt/qtmultimedia/Manifest
new file mode 100644
index 00000000..a4f0a69e
--- /dev/null
+++ b/dev-qt/qtmultimedia/Manifest
@@ -0,0 +1 @@
+DIST qtmultimedia-everywhere-src-6.4.0.tar.xz 5936088 BLAKE2B 7e469db96e145a4bc496daa6547685c84e199a8942452b406a3e661e9da2b8d4306b41fc82551e9257f6f41d2d269cc7a359b6087111d092073b8cdaf683a2c1 SHA512 fd5f0d73374290ecf70d30395b2ddbb05439979a29b5e6b37a1ac40338ffe602ea62b7bb8f3c053b2da35fa9c4101bd6e0a12ee9479c04bb2d63c527c77cb685
diff --git a/dev-qt/qtmultimedia/qtmultimedia-6.4.0.ebuild b/dev-qt/qtmultimedia/qtmultimedia-6.4.0.ebuild
new file mode 100644
index 00000000..508673ac
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-6.4.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Multimedia"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="gstreamer"
+
+RDEPEND="
+	=dev-qt/qtbase-${PV}*[gui,network,widgets]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtshadertools-${PV}*
+	=dev-qt/qtsvg-${PV}*
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/libglvnd
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+src_configure() {
+	# TODO: linux_v4l automagic
+	local mycmakeargs=(
+		-DQT_FEATURE_alsa=off
+		-DQT_FEATURE_pulseaudio=off
+		$(qt_feature gstreamer)
+	)
+
+	qt6-build_src_configure
+}
diff --git a/dev-qt/qtnetworkauth/Manifest b/dev-qt/qtnetworkauth/Manifest
new file mode 100644
index 00000000..db8b9c9f
--- /dev/null
+++ b/dev-qt/qtnetworkauth/Manifest
@@ -0,0 +1 @@
+DIST qtnetworkauth-everywhere-src-6.4.0.tar.xz 144928 BLAKE2B 468ca604f81c3592fc0ffbf6df314cb044a2c5ad53f6464cec069e6a9bae017f35d3e1fa4abe97794e15efa86785ea09e6c733e991e90fb4c868982d074bf46c SHA512 fdefb6ec3477f8da9e78419414f850d94baddfa83b7252c402cde91dabee7cdc51eeee6e761bbadb07d37cef4525131adfd4bdeadb25e977934d4be1a85d8d57
diff --git a/dev-qt/qtnetworkauth/qtnetworkauth-6.4.0.ebuild b/dev-qt/qtnetworkauth/qtnetworkauth-6.4.0.ebuild
new file mode 100644
index 00000000..02ff76da
--- /dev/null
+++ b/dev-qt/qtnetworkauth/qtnetworkauth-6.4.0.ebuild
@@ -0,0 +1,17 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Network authorization library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network,widgets]
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtpositioning/Manifest b/dev-qt/qtpositioning/Manifest
new file mode 100644
index 00000000..ac357c3d
--- /dev/null
+++ b/dev-qt/qtpositioning/Manifest
@@ -0,0 +1 @@
+DIST qtpositioning-everywhere-src-6.4.0.tar.xz 1491860 BLAKE2B 07d9ed3a62ea8b91931749fe5064e3556cc5a6de2d38f428a99a4112c726e16ae01a70a769e353110e74287fb1a5d6090dc011e407b5dc2deeda8e0a7fd2a619 SHA512 298c484ed3e5f4d11c0e865005f8c0ddf422c8bbe9ff725fe01a8960403c55cfbc96ded62e77af4b14e549349501b7555f169e7a4b99435cecfc4b57b5a2b5cb
diff --git a/dev-qt/qtpositioning/qtpositioning-6.4.0.ebuild b/dev-qt/qtpositioning/qtpositioning-6.4.0.ebuild
new file mode 100644
index 00000000..7be915ff
--- /dev/null
+++ b/dev-qt/qtpositioning/qtpositioning-6.4.0.ebuild
@@ -0,0 +1,19 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Physical position determination library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[dbus,gui,widgets]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtserialport-${PV}*
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtquick3d/Manifest b/dev-qt/qtquick3d/Manifest
new file mode 100644
index 00000000..0dd41c44
--- /dev/null
+++ b/dev-qt/qtquick3d/Manifest
@@ -0,0 +1 @@
+DIST qtquick3d-everywhere-src-6.4.0.tar.xz 41490276 BLAKE2B 4743ae4ab1941d404c9c55065801b97642a8f14253603b1bc53cf7074a4fca925eab5791711ca849bddaf796af23a0a406ed72e559ef4e97c5c2b2cc89bcbbf8 SHA512 4fb9e4e40355a83dd19970fc6e942a3a510ce68becd7df92a19ffad7cb4eb6f0bd9b826bde9e0040776018802b756e20978092a6ea4a4d8cc38e7862529610d3
diff --git a/dev-qt/qtquick3d/qtquick3d-6.4.0.ebuild b/dev-qt/qtquick3d/qtquick3d-6.4.0.ebuild
new file mode 100644
index 00000000..6eb36dee
--- /dev/null
+++ b/dev-qt/qtquick3d/qtquick3d-6.4.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt module and API for defining 3D content in Qt QuickTools"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+elif [[ ${QT6_BUILD_TYPE} == live ]]; then
+	# Don't clone qtquick3d-assimp.
+	EGIT_SUBMODULES=()
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[concurrent,network,widgets]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtshadertools-${PV}*
+	=dev-qt/qtquicktimeline-${PV}*
+	media-libs/assimp:=
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DQT_FEATURE_system_assimp=ON
+	)
+
+	qt6-build_src_configure
+}
diff --git a/dev-qt/qtquicktimeline/Manifest b/dev-qt/qtquicktimeline/Manifest
new file mode 100644
index 00000000..b34ae3d4
--- /dev/null
+++ b/dev-qt/qtquicktimeline/Manifest
@@ -0,0 +1 @@
+DIST qtquicktimeline-everywhere-src-6.4.0.tar.xz 112976 BLAKE2B b2370293362dc0cfb7c231788332ff740842318a654db4a8efce475f9b5e5f1bcb72e7777e91ecd1e5f0ac92a9a65c427e69790339173351aebf6cb43ce34521 SHA512 3818056b6f1b16ec443e895ce07582717331b768c036d073735c52b7ce385d8b53a93a9748eaa915885916e9267de7c4e731a5b01dfd5d643b0a594ed58ca577
diff --git a/dev-qt/qtquicktimeline/qtquicktimeline-6.4.0.ebuild b/dev-qt/qtquicktimeline/qtquicktimeline-6.4.0.ebuild
new file mode 100644
index 00000000..0673606b
--- /dev/null
+++ b/dev-qt/qtquicktimeline/qtquicktimeline-6.4.0.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt module for keyframe-based timeline construction"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtserialport/Manifest b/dev-qt/qtserialport/Manifest
new file mode 100644
index 00000000..06394359
--- /dev/null
+++ b/dev-qt/qtserialport/Manifest
@@ -0,0 +1 @@
+DIST qtserialport-everywhere-src-6.4.0.tar.xz 318952 BLAKE2B 806ae200c6a253eefadfff368d6e559129ce2158fea26fa8005eb8d0b3b594d5d68591bbede8b767462731d6557107ad280a721e12fcef88be7dd5ed6aa7c65f SHA512 b2e78302f9ec55b52dfab6f8086a63444f0c6d8ac8dd3b5b39a32c24c8e01d4799b5539144f6e9f4a376c36bcfe4f15c0b9eb5933d45ccc4433e881b9e15b182
diff --git a/dev-qt/qtserialport/qtserialport-6.4.0.ebuild b/dev-qt/qtserialport/qtserialport-6.4.0.ebuild
new file mode 100644
index 00000000..218a7f2d
--- /dev/null
+++ b/dev-qt/qtserialport/qtserialport-6.4.0.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Serial port abstraction library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui,widgets]
+	virtual/libudev:=
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtshadertools/Manifest b/dev-qt/qtshadertools/Manifest
new file mode 100644
index 00000000..92debc1a
--- /dev/null
+++ b/dev-qt/qtshadertools/Manifest
@@ -0,0 +1 @@
+DIST qtshadertools-everywhere-src-6.4.0.tar.xz 1001332 BLAKE2B ac241e69eb5f27a33ab42f70f0b8ba1e2d0a3634cb43a54c9c4c289b7b3cfa6a16357cab23427271405390ec347838a6ed1757a7b425992969f0110dfbc69635 SHA512 80f00b623e546786a2019c979fe8cc54f982665bf3f2d122db1b4d437c847f749a68ed7e316100a853d59ddf04dd10147cad55252a40cd9ff3511db963f3212b
diff --git a/dev-qt/qtshadertools/qtshadertools-6.4.0.ebuild b/dev-qt/qtshadertools/qtshadertools-6.4.0.ebuild
new file mode 100644
index 00000000..755d9ae0
--- /dev/null
+++ b/dev-qt/qtshadertools/qtshadertools-6.4.0.ebuild
@@ -0,0 +1,17 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt APIs and Tools for Graphics Pipelines"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui]
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtsvg/Manifest b/dev-qt/qtsvg/Manifest
new file mode 100644
index 00000000..8a9be9a3
--- /dev/null
+++ b/dev-qt/qtsvg/Manifest
@@ -0,0 +1 @@
+DIST qtsvg-everywhere-src-6.4.0.tar.xz 1726036 BLAKE2B b18473cfef70b159ae40942bc88103a082f6e6e05b7e3e4b1cb310702123be0f4f9cc2f052ebed09904069b586f46adce3116480cb5ee3abbede5bed41a763c4 SHA512 f3a6b3bda1c0a3395528f99b5f7b9647a19aeeda0f97dc96bfb551b9c134a50166d1d58d7d63a411a84bcb482580c6907b2c231d570794a482f42126cec9dd89
diff --git a/dev-qt/qtsvg/qtsvg-6.4.0.ebuild b/dev-qt/qtsvg/qtsvg-6.4.0.ebuild
new file mode 100644
index 00000000..037c2eb0
--- /dev/null
+++ b/dev-qt/qtsvg/qtsvg-6.4.0.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="SVG rendering library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[gui,widgets]
+	sys-libs/zlib:=
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qttools/Manifest b/dev-qt/qttools/Manifest
new file mode 100644
index 00000000..c155251c
--- /dev/null
+++ b/dev-qt/qttools/Manifest
@@ -0,0 +1 @@
+DIST qttools-everywhere-src-6.4.0.tar.xz 8738432 BLAKE2B 0bd6c3e1e4badf16ec74209c1ddc45820bee9403753b6603000fcad8e82b5ee73b4df0f4d346de5c855e0b545e43c17b11ba5702e9caa5b8b2e6280d82a3fab5 SHA512 ff4ed95491d26227b3bfea665fe810572f537a295dda0cffa26b18525961026db0471e7ef04667e3e4b8ae6b92dbedccb0fa77d733274c34d489d448b961ab44
diff --git a/dev-qt/qttools/qttools-6.4.0.ebuild b/dev-qt/qttools/qttools-6.4.0.ebuild
new file mode 100644
index 00000000..23e1c087
--- /dev/null
+++ b/dev-qt/qttools/qttools-6.4.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt Tools Collection"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="
+	assistant designer distancefieldgenerator linguist pixeltool
+	qdbus qdoc qtattributionsscanner qtdiag qtplugininfo
+"
+REQUIRED_USE="linguist? ( designer )"
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network]
+	assistant? ( =dev-qt/qtbase-${PV}*[sql,widgets] )
+	designer? ( =dev-qt/qtbase-${PV}*[widgets] )
+	distancefieldgenerator? (
+		=dev-qt/qtbase-${PV}*[widgets]
+		=dev-qt/qtdeclarative-${PV}*
+	)
+	pixeltool? ( =dev-qt/qtbase-${PV}*[widgets] )
+	qdbus? ( =dev-qt/qtbase-${PV}*[widgets] )
+	qdoc? ( sys-devel/clang:= )
+	qtdiag? ( =dev-qt/qtbase-${PV}*[opengl,widgets] )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(qt_feature assistant)
+		-DQT_FEATURE_commandlineparser=ON
+		$(qt_feature designer)
+		$(qt_feature distancefieldgenerator)
+		$(qt_feature linguist)
+		$(qt_feature pixeltool)
+		$(qt_feature qdbus)
+		$(qt_feature qdoc clang)
+		$(qt_feature qtattributionsscanner)
+		$(qt_feature qtdiag)
+		$(qt_feature qtplugininfo)
+		-DQT_FEATURE_thread=ON
+	)
+
+	qt6-build_src_configure
+}
diff --git a/dev-qt/qtwayland/Manifest b/dev-qt/qtwayland/Manifest
new file mode 100644
index 00000000..1e44f0d0
--- /dev/null
+++ b/dev-qt/qtwayland/Manifest
@@ -0,0 +1 @@
+DIST qtwayland-everywhere-src-6.4.0.tar.xz 836088 BLAKE2B 3efc506e1a0bc63182397d483bf352e21d39c75a7360ee3fe839527451950875748aea5cf62207ffef38b845a12c2bbbefde918d14333d1b194a4ea39b82670f SHA512 745fcc84c936c3f2fa7382291b5013679f9e57d6c680f1d352b0a132ba7cbaaea1495211f8fc4f1af85a81c711794987e4e05284d3ac06c94e92e9b601dae924
diff --git a/dev-qt/qtwayland/qtwayland-6.4.0.ebuild b/dev-qt/qtwayland/qtwayland-6.4.0.ebuild
new file mode 100644
index 00000000..09413e55
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-6.4.0.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+BDEPEND="dev-util/wayland-scanner"
+DEPEND="
+	dev-libs/wayland
+	=dev-qt/qtbase-${PV}*[gui,opengl]
+	=dev-qt/qtdeclarative-${PV}*
+	media-libs/libglvnd
+	x11-libs/libxkbcommon
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtwebchannel/Manifest b/dev-qt/qtwebchannel/Manifest
new file mode 100644
index 00000000..7420e449
--- /dev/null
+++ b/dev-qt/qtwebchannel/Manifest
@@ -0,0 +1 @@
+DIST qtwebchannel-everywhere-src-6.4.0.tar.xz 213096 BLAKE2B 04450f13d6af7996624c5c1e1f1b7f3c6a8ee64088086da3b237c1e1775ac90fad5a7a13ed1213d321f9703565c7ca42cf899dae675a616dd25fa6abad6e7f8a SHA512 5e668869646e9a4a115680004180948777c9cc2b4e6cc3afb4be74e298ec1e7338f61643ac1f46649d39f65e3f50de05d2b635d77bf211105e91dd0d5324fff6
diff --git a/dev-qt/qtwebchannel/qtwebchannel-6.4.0.ebuild b/dev-qt/qtwebchannel/qtwebchannel-6.4.0.ebuild
new file mode 100644
index 00000000..62dd2732
--- /dev/null
+++ b/dev-qt/qtwebchannel/qtwebchannel-6.4.0.ebuild
@@ -0,0 +1,19 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Qt WebChannel"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[concurrent]
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtwebsockets-${PV}*
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-qt/qtwebengine/Manifest b/dev-qt/qtwebengine/Manifest
index d169e66b..2f0b383a 100644
--- a/dev-qt/qtwebengine/Manifest
+++ b/dev-qt/qtwebengine/Manifest
@@ -1,3 +1,4 @@
 DIST qtwebengine-5.15.2-r1-chromium87-ppc64le.tar.xz 28784 BLAKE2B aa101d14446f3282fda8932cc75a249d88b79319f0886d95777292776d94ac5f4fc114c3893b2801fbba6abb14f381172bb14b15b5ffef12413db3a16e4d1ca6 SHA512 3324e0076eb18e2ae2248428d2730cfb3413761514b2bb57e25b8db79248aaaa8098d9f7cebfa08f1a3b39b1d0a382aafed75c5ae8273918909335957921305e
 DIST qtwebengine-5.15.2_p20211019-jumbo-build.patch.bz2 2930 BLAKE2B fca1d1406874d04eafb64bb4d8730512a6307ba44fb99d76f428ca1bd4a303758e0c3bd8f92a59f7bcf62e5b767c5a8ed239028bdb74ad7a8b62abf88d38c101 SHA512 61cbfbe4ff340b75ea8d356e031e932ac03fe65dd009999ff897ca4b0185d1d989490daf75ffeaaabb3e92c870c11c7ff8ad2cd6372f5363b3d774b8ecca6d89
 DIST qtwebengine-5.15.3_p20220406-patchset.tar.xz 35480 BLAKE2B ce6aeebbb3255196611130d04ee7a3907ba45d6d2a283f2433e2176cf67e473e74137b180de0a9998762cc54439bb06825815e81e9f95f9413ce2956ac9308b7 SHA512 47e29a1429dce2db324929af91c8ef8421c75ae48f5a491db71b434f8017a5b1e7475e9938989e331e8e012220852848565242e09747892e1a8a8d3ab7386840
+DIST qtwebengine-everywhere-src-6.4.0.tar.xz 440346968 BLAKE2B ffe9ad9f71034d14f016a71bf3e6034853d5c2b17a3ab3e8aefc1c3a79896363eb2ce41446f16e126ec313608619900ee7ac41750978c28f135df5bbc2e0be5c SHA512 a024781c675c60ca746abb6cd977872b51e3f4a7ff9f934450b82e9b19883c68c0c6c630c28997624f0caceed3c43e8b0658419ecb18cf08fa9081275bedd2a7
diff --git a/dev-qt/qtwebengine/qtwebengine-6.4.0.ebuild b/dev-qt/qtwebengine/qtwebengine-6.4.0.ebuild
new file mode 100644
index 00000000..8e78b6ad
--- /dev/null
+++ b/dev-qt/qtwebengine/qtwebengine-6.4.0.ebuild
@@ -0,0 +1,242 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10} )
+PYTHON_REQ_USE="xml(+)"
+CHROMIUM_VER="102.0.5005.177"
+CHROMIUM_PATCHES_VER="104.0.5112.102"
+
+inherit check-reqs estack flag-o-matic multiprocessing python-any-r1 qt6-build
+
+DESCRIPTION="Library for rendering dynamic web content in Qt6 C++ and QML applications"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="
+	alsa bindist designer geolocation +jumbo-build kerberos pulseaudio screencast
+	+system-ffmpeg +system-icu widgets
+"
+REQUIRED_USE="designer? ( widgets )"
+
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/html5lib[${PYTHON_USEDEP}]')
+	dev-util/gperf
+	dev-util/ninja
+	dev-util/re2c
+	net-libs/nodejs[ssl]
+	sys-devel/bison
+	sys-devel/flex
+"
+RDEPEND="
+	app-arch/snappy:=
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/expat
+	dev-libs/libevent:=
+	dev-libs/libxml2[icu]
+	dev-libs/libxslt
+	dev-libs/re2:=
+	=dev-qt/qtdeclarative-${PV}*
+	=dev-qt/qtwebchannel-${PV}*
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz:=
+	media-libs/lcms:2
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	>=media-libs/libvpx-1.5:=[svc(+)]
+	media-libs/libwebp:=
+	media-libs/opus
+	sys-apps/dbus
+	sys-apps/pciutils
+	sys-libs/zlib[minizip]
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libxcb:=
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libXtst
+	alsa? ( media-libs/alsa-lib )
+	geolocation? ( =dev-qt/qtpositioning-${PV}* )
+	kerberos? ( virtual/krb5 )
+	pulseaudio? ( media-libs/libpulse:= )
+	screencast? ( media-video/pipewire:= )
+	system-ffmpeg? ( media-video/ffmpeg:= )
+	system-icu? ( >=dev-libs/icu-69.1:= )
+	widgets? (
+		=dev-qt/qtbase-${PV}*[widgets]
+	)
+"
+DEPEND="${RDEPEND}
+	media-libs/libglvnd
+"
+
+python_check_deps() {
+	python_has_version "dev-python/html5lib[${PYTHON_USEDEP}]"
+}
+
+qtwebengine_check-reqs() {
+	# bug #307861
+	eshopts_push -s extglob
+	if is-flagq '-g?(gdb)?([1-9])'; then
+		ewarn "You have enabled debug info (probably have -g or -ggdb in your CFLAGS/CXXFLAGS)."
+		ewarn "You may experience really long compilation times and/or increased memory usage."
+		ewarn "If compilation fails, please try removing -g/-ggdb before reporting a bug."
+	fi
+	eshopts_pop
+
+	[[ ${MERGE_TYPE} == binary ]] && return
+
+	# (check-reqs added for bug #570534)
+	#
+	# Estimate the amount of RAM required
+	# Multiplier is *10 because Bash doesn't do floating point maths.
+	# Let's crudely assume ~2GB per compiler job for GCC.
+	local multiplier=20
+
+	# And call it ~1.5GB for Clang.
+	if tc-is-clang ; then
+		multiplier=15
+	fi
+
+	local CHECKREQS_DISK_BUILD="7G"
+	local CHECKREQS_DISK_USR="150M"
+	if ! has "distcc" ${FEATURES} ; then
+		# bug #830661
+		# Not super realistic to come up with good estimates for distcc right now
+		local CHECKREQS_MEMORY=$(($(makeopts_jobs)*multiplier/10))G
+	fi
+
+	check-reqs_${EBUILD_PHASE_FUNC}
+}
+
+pkg_pretend() {
+	qtwebengine_check-reqs
+}
+
+pkg_setup() {
+	qtwebengine_check-reqs
+	python-any-r1_pkg_setup
+}
+
+pkg_preinst() {
+	elog "This version of Qt WebEngine is based on Chromium version ${CHROMIUM_VER}, with"
+	elog "additional security fixes up to ${CHROMIUM_PATCHES_VER}. Extensive as it is, the"
+	elog "list of backports is impossible to evaluate, but always bound to be behind"
+	elog "Chromium's release schedule."
+	elog "In addition, various online services may deny service based on an outdated"
+	elog "user agent version (and/or other checks). Google is already known to do so."
+	elog
+	elog "tldr: Your web browsing experience will be compromised."
+}
+
+src_unpack() {
+	# bug 307861
+	eshopts_push -s extglob
+	if is-flagq '-g?(gdb)?([1-9])'; then
+		ewarn
+		ewarn "You have enabled debug info (probably have -g or -ggdb in your CFLAGS/CXXFLAGS)."
+		ewarn "You may experience really long compilation times and/or increased memory usage."
+		ewarn "If compilation fails, please try removing -g/-ggdb before reporting a bug."
+		ewarn
+	fi
+	eshopts_pop
+
+	case ${QT6_BUILD_TYPE} in
+		live)    git-r3_src_unpack ;&
+		release) default ;;
+	esac
+}
+
+src_prepare() {
+	# bug 620444 - ensure local headers are used
+	find . -type f -name "*.pr[fio]" -exec \
+		sed -i -e 's|INCLUDEPATH += |&$${QTWEBENGINE_ROOT}_build/include $${QTWEBENGINE_ROOT}/include |' {} + || die
+
+	if use system-icu; then
+		# Sanity check to ensure that bundled copy of ICU is not used.
+		# Whole src/3rdparty/chromium/third_party/icu directory cannot be deleted because
+		# src/3rdparty/chromium/third_party/icu/BUILD.gn is used by build system.
+		# If usage of headers of bundled copy of ICU occurs, then lists of shim headers in
+		# shim_headers("icui18n_shim") and shim_headers("icuuc_shim") in
+		# src/3rdparty/chromium/third_party/icu/BUILD.gn should be updated.
+		local file
+		while read file; do
+			echo "#error This file should not be used!" > "${file}" || die
+		done < <(find src/3rdparty/chromium/third_party/icu -type f "(" -name "*.c" -o -name "*.cpp" -o -name "*.h" ")" 2>/dev/null)
+	fi
+
+	qt6-build_src_prepare
+}
+
+src_configure() {
+	export NINJA_PATH="${BROOT}"/usr/bin/ninja
+	export NINJAFLAGS="${NINJAFLAGS:--j$(makeopts_jobs) -l$(makeopts_loadavg "${MAKEOPTS}" 0) -v}"
+
+	local mycmakeargs=(
+		#-DQT_FEATURE_accessibility=off
+		#-DQT_FEATURE_force_asserts=off
+		#-DQT_FEATURE_opengl=off
+		#-DQT_FEATURE_printer=off
+		-DQT_FEATURE_qtpdf_build=off
+		-DQT_FEATURE_qtpdf_quick_build=off
+		-DQT_FEATURE_qtpdf_widgets_build=off
+		-DQT_FEATURE_qtwebengine_build=on
+		-DQT_FEATURE_qtwebengine_quick_build=on
+		-DQT_FEATURE_qtwebengine_widgets_build=on
+		#-DQT_FEATURE_ssl=off
+		#-DQT_FEATURE_static=off
+		#-DQT_FEATURE_system_zlib=off
+		#-DQT_FEATURE_system_png=off
+		#-DQT_FEATURE_system_jpeg=off
+		#-DQT_FEATURE_system_freetype=off
+		#-DQT_FEATURE_system_harfbuzz=off
+		#-DQT_FEATURE_use_gold_linker=off
+		#-DQT_FEATURE_use_lld_linker=off
+		-DQT_FEATURE_webengine_embedded_build=off
+		-DQT_FEATURE_webengine_extensions=on
+		#-DQT_FEATURE_webengine_full_debug_info=$(usex debug)
+		-DQT_FEATURE_webengine_geolocation=$(usex geolocation on off)
+		-DQT_FEATURE_webengine_jumbo_build=$(usex jumbo-build)
+		#-DQT_FEATURE_webengine_jumbo_file_merge_limit
+		-DQT_FEATURE_webengine_kerberos=$(usex kerberos on off)
+		-DQT_FEATURE_webengine_native_spellchecker=off
+		-DQT_FEATURE_webengine_ozone_x11=on
+		-DQT_FEATURE_webengine_pepper_plugins=on
+		-DQT_FEATURE_webengine_proprietary_codecs=$(usex bindist off on)
+		-DQT_FEATURE_webengine_printing_and_pdf=on
+		-DQT_FEATURE_webengine_sanitizer=on
+		-DQT_FEATURE_webengine_spellchecker=on
+		-DQT_FEATURE_webengine_system_opus=on
+		-DQT_FEATURE_webengine_system_libwebp=on
+		-DQT_FEATURE_webengine_system_alsa=$(usex alsa on off)
+		-DQT_FEATURE_webengine_system_ffmpeg=$(usex system-ffmpeg)
+		-DQT_FEATURE_webengine_system_icu=$(usex system-icu)
+		-DQT_FEATURE_webengine_system_libevent=on
+		-DQT_FEATURE_webengine_system_libpci=on
+		-DQT_FEATURE_webengine_system_libpng=on
+		-DQT_FEATURE_webengine_system_pulseaudio=$(usex pulseaudio on off)
+		-DQT_FEATURE_webengine_system_zlib=on
+		-DQT_FEATURE_webengine_webchannel=on
+		-DQT_FEATURE_webengine_webrtc=on
+		-DQT_FEATURE_webengine_webrtc_pipewire=$(usex screencast on off)
+		#-DQT_FEATURE_xcb=off
+	)
+
+	qt6-build_src_configure
+}
diff --git a/dev-qt/qtwebsockets/Manifest b/dev-qt/qtwebsockets/Manifest
new file mode 100644
index 00000000..a04e46a6
--- /dev/null
+++ b/dev-qt/qtwebsockets/Manifest
@@ -0,0 +1 @@
+DIST qtwebsockets-everywhere-src-6.4.0.tar.xz 266400 BLAKE2B cbe11902a3743e54aea2e75141360fc18d57d44ffed7e862de80ce374fe35b94862d12d3408328c80ced07cae24f6df0064303947b7c4b0a758866cc911b4f0a SHA512 dc2e86332a7c493afa66c3844443c3a5dbe830786f1127a0eac66594bb254ba1294389c24221d1984044caddc4afa1e4f9832382b403c7c9a8bf5c9dd21d53d0
diff --git a/dev-qt/qtwebsockets/qtwebsockets-6.4.0.ebuild b/dev-qt/qtwebsockets/qtwebsockets-6.4.0.ebuild
new file mode 100644
index 00000000..6b0e253a
--- /dev/null
+++ b/dev-qt/qtwebsockets/qtwebsockets-6.4.0.ebuild
@@ -0,0 +1,18 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Implementation of the WebSocket protocol for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+DEPEND="
+	=dev-qt/qtbase-${PV}*[network]
+	=dev-qt/qtdeclarative-${PV}*
+"
+RDEPEND="${DEPEND}"