1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/traits/traits-5.1.0.ebuild b/dev-python/traits/traits-5.1.0.ebuild
new file mode 100644
index 000000000..5685ceeb5
--- /dev/null
+++ b/dev-python/traits/traits-5.1.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Enthought Tool Suite: Explicitly typed attributes for Python"
+HOMEPAGE="http://docs.enthought.com/traits/
+	https://github.com/enthought/traits
+	https://pypi.org/project/traits/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		${RDEPEND}
+		)"
+
+python_prepare_all() {
+	sed -i -e "s/'-O3'//g" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	nosetests || die
+}