x11-apps/igt-gpu-tools: Version bump to 1.27.1

* Add Python 3.11 compatibility (bug #897342)
* Add runner? ( tests ) to REQUIRED_USE (bug #800680)

Closes: https://bugs.gentoo.org/800680
Closes: https://bugs.gentoo.org/897342
Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 110 insertions, 2 deletions

diff --git a/x11-apps/igt-gpu-tools/Manifest b/x11-apps/igt-gpu-tools/Manifest
index 5fef12f3e0ef..b20e76beee7c 100644
--- a/x11-apps/igt-gpu-tools/Manifest
+++ b/x11-apps/igt-gpu-tools/Manifest
@@ -1 +1,2 @@
 DIST igt-gpu-tools-1.26.tar.xz 1573468 BLAKE2B 31fa9cd61fd9a120c72e78cb5ecbc686477ae82572c702bdd6bbc11ba49dc052b7cf52fa486b93e51c87389d73f892577c1d22ebe71d6f50b1565f32355021d1 SHA512 6eb67f68da1c79fac61e5abd57433ef51dbeb2b6f0923dc84aefb81d7059fbc94378fadcd7321a8f059edd9bac640032bf53c3aa058cf570fe5c31924396af8f
+DIST igt-gpu-tools-1.27.1.tar.xz 2321940 BLAKE2B b6c4fee31c97cd5005c1f2cd5c18c181582adfb27e92444a8e78d1c105acb78a424bd4e4af8d13333776c81531fbfd24dc4b7db0da9858f5b803f64962d6269d SHA512 20923505e9afe6e5064bf8f4056e027ff0321cd29d8982157a608369aea6fbef24c93756de96ef6296e09d539957fc6cdad4097cbab5af33f8828f762da0d8c0
diff --git a/x11-apps/igt-gpu-tools/igt-gpu-tools-1.27.1.ebuild b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.27.1.ebuild
new file mode 100644
index 000000000000..e5263c2dbe35
--- /dev/null
+++ b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.27.1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+EGIT_REPO_URI="https://gitlab.freedesktop.org/drm/${PN}.git"
+if [[ ${PV} = *9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit ${GIT_ECLASS} meson python-any-r1
+
+DESCRIPTION="Intel GPU userland tools"
+
+HOMEPAGE="https://01.org/linuxgraphics https://gitlab.freedesktop.org/drm/igt-gpu-tools"
+if [[ ${PV} = *9999* ]]; then
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.x.org/releases/individual/app/${P}.tar.xz"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="chamelium doc man overlay runner tests unwind valgrind video_cards_amdgpu video_cards_intel video_cards_nouveau X xv"
+REQUIRED_USE="
+	|| ( video_cards_amdgpu video_cards_intel video_cards_nouveau )
+	overlay? (
+		video_cards_intel
+		|| ( X xv )
+	)
+	doc? ( tests )
+	runner? ( tests )
+"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/elfutils
+	dev-libs/glib:2
+	sys-apps/kmod:=
+	sys-libs/zlib:=
+	sys-process/procps:=
+	virtual/libudev:=
+	>=x11-libs/cairo-1.12.0[X?]
+	>=x11-libs/libdrm-2.4.82[video_cards_amdgpu?,video_cards_intel?,video_cards_nouveau?]
+	>=x11-libs/libpciaccess-0.10
+	x11-libs/pixman
+	chamelium? (
+		dev-libs/xmlrpc-c:=[curl]
+		sci-libs/gsl:=
+		media-libs/alsa-lib:=
+	)
+	overlay? (
+		>=x11-libs/libXrandr-1.3
+		xv? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXv
+		)
+	)
+	runner? ( dev-libs/json-c:= )
+	unwind? ( sys-libs/libunwind:= )
+	valgrind? ( dev-util/valgrind )
+	"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-util/gtk-doc-1.25-r1 )
+	man? ( dev-python/docutils )
+	overlay? (
+		>=dev-util/peg-0.1.18
+		x11-base/xorg-proto
+	)
+	video_cards_intel? (
+		sys-devel/bison
+		sys-devel/flex
+	)
+"
+BDEPEND="${PYTHON_DEPS}"
+
+src_prepare() {
+	sed -e "s/find_program('rst2man-3'/find_program('rst2man.py', 'rst2man-3'/" -i man/meson.build
+	default_src_prepare
+}
+
+src_configure() {
+	local gpus=""
+	use video_cards_amdgpu  && gpus+="amdgpu,"
+	use video_cards_intel   && gpus+="intel,"
+	use video_cards_nouveau && gpus+="nouveau,"
+
+	local overlay_backends=""
+	use overlay && use xv && overlay_backends+="xv,"
+	use overlay && use X && overlay_backends+="x,"
+
+	local emesonargs=(
+		$(meson_feature chamelium)
+		$(meson_feature doc docs)
+		$(meson_feature man)
+		$(meson_feature overlay)
+		$(meson_feature runner)
+		$(meson_feature tests)
+		$(meson_feature valgrind)
+		$(meson_feature unwind libunwind)
+		-Doverlay_backends=${overlay_backends%?}
+		-Dlibdrm_drivers=${gpus%?}
+	)
+	meson_src_configure
+}
diff --git a/x11-apps/igt-gpu-tools/igt-gpu-tools-9999.ebuild b/x11-apps/igt-gpu-tools/igt-gpu-tools-9999.ebuild
index 7bc5bd711ea5..e5263c2dbe35 100644
--- a/x11-apps/igt-gpu-tools/igt-gpu-tools-9999.ebuild
+++ b/x11-apps/igt-gpu-tools/igt-gpu-tools-9999.ebuild
@@ -1,13 +1,13 @@
 # Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 EGIT_REPO_URI="https://gitlab.freedesktop.org/drm/${PN}.git"
 if [[ ${PV} = *9999* ]]; then
 	GIT_ECLASS="git-r3"
 fi
 
-PYTHON_COMPAT=( python3_{9..10} )
+PYTHON_COMPAT=( python3_{9..11} )
 inherit ${GIT_ECLASS} meson python-any-r1
 
 DESCRIPTION="Intel GPU userland tools"
@@ -29,6 +29,7 @@ REQUIRED_USE="
 		|| ( X xv )
 	)
 	doc? ( tests )
+	runner? ( tests )
 "
 RESTRICT="test"