dev-python/openstacksdk: add 0.101.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 142400f3b752..c446601bb661 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1 +1,2 @@
 DIST openstacksdk-0.100.0.tar.gz 1065692 BLAKE2B 7941cb9a14f10924953ad114f9bce4847b7e26bbea4622790503209ab70a01c254f2ec59d3f794f64d1ecc8f320a9a2be2db8015cccad8b20fe06dc1e72683d0 SHA512 c3e47510518bc4abac78aab654f6f8aa7c0deec3f4355ec7ea064ffa32c1862a9015806fd04cc1975c3d7e688e9c5ee66e3837baa21ae6c82db8f39b4b8f8330
+DIST openstacksdk-0.101.0.tar.gz 1072136 BLAKE2B f73103fd65bdf11340b765918bc226b2d681a9846cba11f0a8dbd5d97f300690f82c1846e10ebbab413900f4e4199aa81de9b6213d07bcbcc817233758ac78a9 SHA512 95580b7c53c901ef21280420c6b27dfac20341c12f5490e5c7611df3f8c3d309b5b967f8d574e6e2d939f5224b8785bb5e07fbb3941955530cfbbc8c0049b269
diff --git a/dev-python/openstacksdk/openstacksdk-0.101.0.ebuild b/dev-python/openstacksdk/openstacksdk-0.101.0.ebuild
new file mode 100644
index 000000000000..c7e4af79b1de
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-0.101.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.20[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/munch-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus_client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}