summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2021-11-29 14:25:19 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2021-11-29 14:28:36 +0100
commit056ab10a41566b89bfd7db130155fcf16baa2345 (patch)
tree409841d83868507e90a7fe7c28f907b54a84835e
parentapp-doc/vilearn: update to EAPI 8 (diff)
downloadgentoo-056ab10a41566b89bfd7db130155fcf16baa2345.tar.gz
gentoo-056ab10a41566b89bfd7db130155fcf16baa2345.tar.bz2
gentoo-056ab10a41566b89bfd7db130155fcf16baa2345.zip
media-sound/yarock: Add missing IUSE=mpv dependency, EAPI-8
Closes: https://bugs.gentoo.org/827626 Package-Manager: Portage-3.0.28, Repoman-3.0.3 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
-rw-r--r--media-sound/yarock/yarock-1.4.0-r2.ebuild61
1 files changed, 61 insertions, 0 deletions
diff --git a/media-sound/yarock/yarock-1.4.0-r2.ebuild b/media-sound/yarock/yarock-1.4.0-r2.ebuild
new file mode 100644
index 00000000000..c7f4cd5e45b
--- /dev/null
+++ b/media-sound/yarock/yarock-1.4.0-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="Yarock_${PV}_Sources"
+inherit cmake
+
+DESCRIPTION="Qt-based music player"
+HOMEPAGE="https://seb-apps.github.io/yarock/"
+SRC_URI="https://launchpad.net/${PN}/1.x/${PV}/+download/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="mpv phonon vlc"
+
+RDEPEND="
+ dev-cpp/htmlcxx
+ dev-qt/qtcore:5
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtsql:5[sqlite]
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ media-libs/taglib
+ x11-libs/libX11
+ mpv? ( media-video/mpv:= )
+ phonon? ( >=media-libs/phonon-4.11.0 )
+ vlc? ( media-video/vlc:= )
+"
+DEPEND="${RDEPEND}
+ dev-qt/qtconcurrent:5
+ dev-qt/qtx11extras:5
+"
+BDEPEND="
+ dev-qt/linguist-tools:5
+"
+
+DOCS=( CHANGES.md README.md )
+
+src_prepare() {
+ cmake_src_prepare
+ sed -e "/^install.*org.yarock.appdata.xml/s:share/appdata:share/metadata:" \
+ -i CMakeLists.txt || die
+ sed -e "/^Version/d" \
+ -i data/org.yarock.desktop || die
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DENABLE_QT5=ON
+ -DENABLE_MPV=$(usex mpv)
+ -DENABLE_PHONON=$(usex phonon)
+ -DENABLE_VLC=$(usex vlc)
+ )
+
+ cmake_src_configure
+}