kde-frameworks/breeze-icons: 5.105.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 57 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index fe746e770900..3a678707c6f4 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1,2 +1,3 @@
 DIST breeze-icons-5.102.0.tar.xz 2163332 BLAKE2B e49e817d03f297ec4837c9045bfc02329354f2339988042c48c74315f2c096c86cc69354d6a74e774b29c8bc04d33efc8c3a7590c8ccee29ee9cd99f193b3c29 SHA512 4660582257a542c2bc215fc3c6281fedfc1c8c3249548358e5eb518c05a0c5f8811e05561c971a720459c1e55b9196a7a130934009069e5b0e809d749c2bc11f
 DIST breeze-icons-5.104.0.tar.xz 2163596 BLAKE2B 177fc8fd42c48b89de3f407448bf2d08ec8bb7128ae5b85020a369afbe90092f150a649ae88a90ee697fc396b2ac0e93181a652f41145a50e0166ba1541b4e2f SHA512 3281111a8547d1ce03311b2f0f2a5239bc3ce923200277ea01cf6ce16c77f84823d3d7dba0dbda8155823a30fa16d009c2eda83fbb5355f6f1e6f87cf36df657
+DIST breeze-icons-5.105.0.tar.xz 2165892 BLAKE2B 592f8948ccc5c11d458c10bbc9737347c44dfbb90364cee799318c836cfac1bd9b188c9df9b1b8b95754c9d181ab0b64223f612ee3ed736356a13ebaedcf23e6 SHA512 d3150a68a7fbd9aef67441ec0bb4f0e1e0d28d9bb55616271443edc8847f06f87398e8e3461c3246288998cc86913d6df8a882ae4bc105095184f4d81759e4e3
diff --git a/kde-frameworks/breeze-icons/breeze-icons-5.105.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-5.105.0.ebuild
new file mode 100644
index 000000000000..ad5e11ad5a7d
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-5.105.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{9..11} )
+inherit cmake frameworks.kde.org python-any-r1 xdg-utils
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}