dev-python/tempest: add 30.0.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index 0796b4d38a67..7accabf8fa65 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-29.2.0.tar.gz 1092824 BLAKE2B cad7284ab5a5a39a1a5bdf9f2365a85d337e4ebe17243bc3692a98402ef7f11b27b94e0252d9d427f358c343b736b500db5386098950c88b09f23d87de9ad856 SHA512 4042bce9c5d7cd26d652189d82ee91ac43d73a515b690820dfe05b70c2e792ec6f3bb0be5566bb37e81965015f62773414c8a16cc77512b1e52f141eafbd542d
+DIST tempest-30.0.0.tar.gz 1110715 BLAKE2B b697ecbced21124719e6b1d7ebd2c4f8ba83528a84da0b8f8109c155b61124581b97c180bbdc6885ae53850fb28daed25772d12be5026c44ecc3fe4f0dad98a3 SHA512 fa9be713ccb130ad065628592f59bebda3dc1fa8222ab3c382ec5b299504dc0a730f2110ef80f98bbdd1288b5785ab745fe39b721b77f7343983c1bc0a036f19
diff --git a/dev-python/tempest/tempest-30.0.0.ebuild b/dev-python/tempest/tempest-30.0.0.ebuild
new file mode 100644
index 000000000000..e9f0d2aad3d1
--- /dev/null
+++ b/dev-python/tempest/tempest-30.0.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="https://pypi.org/project/tempest/ https://docs.openstack.org/tempest/latest/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1 OS_TEST_TIMEOUT=320
+	eunittest -b -s tempest/tests -t .
+}
+
+src_install() {
+	distutils-r1_src_install
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}