x11-misc/lightdm-gtk-greeter: add 2.0.9

Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/x11-misc/lightdm-gtk-greeter/Manifest b/x11-misc/lightdm-gtk-greeter/Manifest
index bbc1b59a703e..dc00e0ef1e3a 100644
--- a/x11-misc/lightdm-gtk-greeter/Manifest
+++ b/x11-misc/lightdm-gtk-greeter/Manifest
@@ -1,2 +1,3 @@
 DIST lightdm-gentoo-patch-2.tar.gz 695543 BLAKE2B 62e21dd413b90053160f774663d89c81b3c9d8c4a040023f4ce50bf775a2f036e0be6ed16ae767eb5b04586a27fdbf41eb56f777340b2d56633738a126c3d575 SHA512 8d9bfdee71ab1871de33e134b11bba409cc493876e5ae9534956100ff6af6c8748b29de9082ecf8b771ccac4c8c2024e15e93332165171dfe93eb99c9a834274
 DIST lightdm-gtk-greeter-2.0.8.tar.gz 583426 BLAKE2B ae06ebbc07efe5c0131c07b293671f24683699eb84f12222de8165428e935b98bbf9d1e107eaeca8f10e725a6a11c97d4f4c3d415ada0b0876b0b0a99f21d1ee SHA512 59cad69fd7f17b6a416944804be80f306ed51ee0c55826975c8564f432e8098043b677f6452e9afa290c6ef37ebdc632cd8b79e7a0a712a3407ddbf9f200b0db
+DIST lightdm-gtk-greeter-2.0.9.tar.gz 602540 BLAKE2B 33c7df912ee9faa46c97e7a458f400b13d7d746521de58b1c63ec845574c45374a27fe21718ac78a33a729617941cff01802c4736d1d3066d001065a57acc264 SHA512 05d786d31e447cacc28ddb06e89e91623b137665badcebd82ac7f9e8ff745a01aadf406e25ebd2c6594915fe8a90a242ef065ad46fd9ee73cd6e8c2879f70158
diff --git a/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.9.ebuild b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.9.ebuild
new file mode 100644
index 000000000000..40ca5f48ebff
--- /dev/null
+++ b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.9.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools xdg-utils
+
+DESCRIPTION="LightDM GTK+ Greeter"
+HOMEPAGE="https://github.com/Xubuntu/lightdm-gtk-greeter"
+SRC_URI="https://github.com/Xubuntu/${PN}/releases/download/${P}/${P}.tar.gz
+	branding? ( https://dev.gentoo.org/~marecki/dists/x11-misc/lightdm-gtk-greeter/lightdm-gentoo-patch-2.tar.gz )"
+
+LICENSE="GPL-3 LGPL-3
+	branding? ( CC-BY-3.0 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="appindicator branding"
+
+DEPEND="x11-libs/gtk+:3
+	>=x11-misc/lightdm-1.2.2
+	appindicator? (
+		dev-libs/ayatana-ido
+		dev-libs/libayatana-indicator:3
+	)"
+
+BDEPEND="
+	dev-build/xfce4-dev-tools
+	dev-util/intltool
+	sys-devel/gettext
+"
+
+RDEPEND="${DEPEND}
+	x11-themes/gnome-themes-standard
+	>=x11-themes/adwaita-icon-theme-3.14.1"
+
+GENTOO_BG="gentoo-bg_65.jpg"
+
+src_prepare() {
+	# Ok, this has to be fixed in the tarball but I am too lazy to do it.
+	# I will fix this once I decide to update the tarball with a new gentoo
+	# background
+	# Bug #404467
+	if use branding; then
+		sed \
+			-e "/xft-hintstyle/s:slight:hintslight:" \
+			-e "/background/s:=.*:=/usr/share/lightdm/backgrounds/${GENTOO_BG}:" \
+			-i "${WORKDIR}"/${PN}.conf || die
+		# Add back the reboot/shutdown buttons
+		echo 'indicators=~host;~spacer;~clock;~spacer;~session;~language;~a11y;~power;~' \
+			>> "${WORKDIR}"/${PN}.conf || die
+	fi
+	default
+
+	# Fix docdir
+	sed "/^docdir/s@${PN}@${PF}@" -i data/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-kill-on-sigterm
+		--enable-at-spi-command="${EPREFIX}/usr/libexec/at-spi-bus-launcher --launch-immediately"
+		--with-libindicator=ayatana
+		$(use_enable appindicator libindicator)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use branding; then
+		insinto /etc/lightdm/
+		doins "${WORKDIR}"/${PN}.conf
+		insinto /usr/share/lightdm/backgrounds/
+		doins "${WORKDIR}"/${GENTOO_BG}
+		newdoc "${WORKDIR}"/README.txt README-background.txt
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}