dev-python/qtconsole: Bump to 5.5.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/dev-python/qtconsole/Manifest b/dev-python/qtconsole/Manifest
index c15dc441bb26..2f7fdfd60ec0 100644
--- a/dev-python/qtconsole/Manifest
+++ b/dev-python/qtconsole/Manifest
@@ -1,2 +1,3 @@
 DIST qtconsole-5.4.3.tar.gz 437303 BLAKE2B ead6676dabf342a74c30ecba1f280e697c7e58fb970813a572bcacf4adbc71e525df4323b50c30100433373e89eeea464dc382844066416e121a0f1c140487db SHA512 9c2061441775daa3045c1788ed57048de9197938a927647197d29a0b7cada836d5fe4e3329b5126c984064070a275cccbe0341622c3b8591f63842a619b859e8
 DIST qtconsole-5.4.4.tar.gz 437213 BLAKE2B 2def481c7ceb29c8ce92dfb96055310a8ee3a664a77c76da0eac672c6fd036326402a47cdaab25d504a855172067ae73e7f94b874545951674395d82f18374b5 SHA512 95d00a7896579eeba75896dd96efe9f07a54a687eca4ec2c4d9c7cf05029570788cd23267682ee4bce9943cf4d6cb36d7bd1d77be66f6bfd0f37e7d15e0d8f0f
+DIST qtconsole-5.5.0.tar.gz 438967 BLAKE2B f9833f18ecb0ddadd55793d3dc38b9f421add4ac22cd98849f8770b5762df01c9e4e0e6f5c42baf8e3715e87aa0b6ca5a207f5d2d954b1f6b2a5f9e2664f7669 SHA512 8e128ae3988b29398eb4b0cde4f18668c6ad22718c6f8d1c0feec09eb632f5b3c2bdf004932b8e2931eb4553f70c4a6d73104dcb611b09a41a744f0f8036a7eb
diff --git a/dev-python/qtconsole/qtconsole-5.5.0.ebuild b/dev-python/qtconsole/qtconsole-5.5.0.ebuild
new file mode 100644
index 000000000000..5ceced5c22c0
--- /dev/null
+++ b/dev-python/qtconsole/qtconsole-5.5.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Qt-based console for Jupyter with support for rich media output"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/qtconsole/
+	https://pypi.org/project/qtconsole/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~x86"
+
+RDEPEND="
+	>=dev-python/ipykernel-4.1[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-4.1.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.2.2_p1[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-2.4.0[${PYTHON_USEDEP},gui,printsupport,svg]
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+		dev-python/QtPy[${PYTHON_USEDEP},svg,testlib]
+	)
+"
+
+PDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO; expects exact HTML, so perhaps fragile
+		qtconsole/tests/test_jupyter_widget.py::TestJupyterWidget::test_other_output
+	)
+	local -x QT_API
+	for QT_API in pyqt5 pyqt6 pyside2 pyside6; do
+		if has_version "dev-python/QtPy[${QT_API}]"; then
+			local -x PYTEST_QT_API=${QT_API}
+			einfo "Testing with ${QT_API}"
+			nonfatal epytest ||
+				die "Tests failed with ${EPYTHON} / ${QT_API}"
+		fi
+	done
+}