sys-apps/less: bump beta & add live ebuild

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>

3 files changed, 80 insertions, 2 deletions

diff --git a/sys-apps/less/Manifest b/sys-apps/less/Manifest
index 0c602fcbaf77..8b826e5261fa 100644
--- a/sys-apps/less/Manifest
+++ b/sys-apps/less/Manifest
@@ -1,2 +1,2 @@
 DIST less-608.tar.gz 362346 BLAKE2B 988940745fef1222c43b0bf4edec7cc7206ded0ac5d89d3faf4dab706a249913581c2fe7aa6063cf3d717176ed07b69299d3e791ba8a60358483fe9d1bf7f7c6 SHA512 7945b7f88921832ebb1b45fba8cbb449ee0133342796b654a52c146dfff3d84db18724ee84e53349eeea6017a0ebe2d8eb5366210275981dde7bb7190118fa66
-DIST less-617-beta.tar.gz 366906 BLAKE2B ccadbdefc33b2df416058cb065afc5e4f8278d49615bf1b25c47180539d080f29f574c4871d0424cc6413b70e7fab99799d4a2661ab8bbc1894526603b94dbff SHA512 16365e79d0fa1e5c70a182e209a1ecc8c33242dcc973680f036ed09054dfd6910d63d79cb080cb1b2cffc5b7d8850666116ad7ee6de1db6140f2fd58ad00ad19
+DIST less-618-beta.tar.gz 365786 BLAKE2B b1957ab49059a2df14d8ba5daf1d8543adc4546c44b537d86959e2e1fe2df93f99ceb8ef47097b6f84f75f7740e161269b4e1d5dd263b8171212c87e650a02fe SHA512 6197aa20c77a846e53b376aa63c2863242c40663e72213f66c3597bd8c38a9458163d0c9ba0ca7690574c07348bb7d3e108c3b50dbbedbc9e5707a14d946b280
diff --git a/sys-apps/less/less-617.ebuild b/sys-apps/less/less-618_beta.ebuild
index cb210766d048..9add6f6c1d52 100644
--- a/sys-apps/less/less-617.ebuild
+++ b/sys-apps/less/less-618_beta.ebuild
@@ -5,6 +5,11 @@ EAPI=8
 WANT_AUTOMAKE=none
 WANT_LIBTOOL=none
 
+if [[ $PV == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/gwsw/less"
+	inherit git-r3
+fi
+
 inherit autotools
 
 # Releases are usually first a beta then promoted to stable if no
@@ -12,9 +17,12 @@ inherit autotools
 # the beta versions. It's okay to keyword beta versions if they fix
 # a serious bug, but otherwise try to avoid it.
 
+MY_PV=${PV/_beta/-beta}
+MY_P=${PN}-${MY_PV}
 DESCRIPTION="Excellent text file viewer"
 HOMEPAGE="http://www.greenwoodsoftware.com/less/"
-SRC_URI="http://www.greenwoodsoftware.com/less/${P}-beta.tar.gz"
+[ $PV != 9999 ] && SRC_URI="http://www.greenwoodsoftware.com/less/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P/?beta}
 
 LICENSE="|| ( GPL-3 BSD-2 )"
 SLOT="0"
@@ -28,6 +36,8 @@ RDEPEND="${DEPEND}"
 
 src_prepare() {
 	default
+	# Per upstream README to prepare live build
+	[ $PV == 9999 ] && emake -f Makefile.aut distfiles
 	# Upstream uses unpatched autoconf-2.69, which breaks with clang-16.
 	# https://bugs.gentoo.org/870412
 	eautoreconf
diff --git a/sys-apps/less/less-9999.ebuild b/sys-apps/less/less-9999.ebuild
new file mode 100644
index 000000000000..9add6f6c1d52
--- /dev/null
+++ b/sys-apps/less/less-9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+WANT_AUTOMAKE=none
+WANT_LIBTOOL=none
+
+if [[ $PV == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/gwsw/less"
+	inherit git-r3
+fi
+
+inherit autotools
+
+# Releases are usually first a beta then promoted to stable if no
+# issues were found. Upstream explicitly ask "to not generally distribute"
+# the beta versions. It's okay to keyword beta versions if they fix
+# a serious bug, but otherwise try to avoid it.
+
+MY_PV=${PV/_beta/-beta}
+MY_P=${PN}-${MY_PV}
+DESCRIPTION="Excellent text file viewer"
+HOMEPAGE="http://www.greenwoodsoftware.com/less/"
+[ $PV != 9999 ] && SRC_URI="http://www.greenwoodsoftware.com/less/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P/?beta}
+
+LICENSE="|| ( GPL-3 BSD-2 )"
+SLOT="0"
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="pcre"
+
+DEPEND=">=app-misc/editor-wrapper-3
+	>=sys-libs/ncurses-5.2:0=
+	pcre? ( dev-libs/libpcre2 )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	# Per upstream README to prepare live build
+	[ $PV == 9999 ] && emake -f Makefile.aut distfiles
+	# Upstream uses unpatched autoconf-2.69, which breaks with clang-16.
+	# https://bugs.gentoo.org/870412
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-regex=$(usex pcre pcre2 posix)
+		--with-editor="${EPREFIX}"/usr/libexec/editor
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	newbin "${FILESDIR}"/lesspipe-r1.sh lesspipe
+	newenvd "${FILESDIR}"/less.envd 70less
+}
+
+pkg_preinst() {
+	if has_version "<${CATEGORY}/${PN}-483-r1" ; then
+		elog "The lesspipe.sh symlink has been dropped.  If you are still setting"
+		elog "LESSOPEN to that, you will need to update it to '|lesspipe %s'."
+		elog "Colorization support has been dropped.  If you want that, check out"
+		elog "the new app-text/lesspipe package."
+	fi
+}