app-misc/sl: update EAPI 6 -> 8, respect LDFLAGS

Closes: https://bugs.gentoo.org/762937
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/app-misc/sl/files/sl-5.02-LDFLAGS.patch b/app-misc/sl/files/sl-5.02-LDFLAGS.patch
new file mode 100644
index 000000000000..22416a71594f
--- /dev/null
+++ b/app-misc/sl/files/sl-5.02-LDFLAGS.patch
@@ -0,0 +1,8 @@
+--- a/Makefile
++++ b/Makefile
+@@ -10,4 +10,4 @@ CC=gcc
+ CFLAGS=-O
+ 
+ sl: sl.c sl.h
+-	$(CC) $(CFLAGS) -o sl sl.c -lncurses
++	$(CC) $(CFLAGS) -o sl $(LDFLAGS) sl.c -lncurses
diff --git a/app-misc/sl/sl-5.02-r1.ebuild b/app-misc/sl/sl-5.02-r1.ebuild
new file mode 100644
index 000000000000..50d9b2537716
--- /dev/null
+++ b/app-misc/sl/sl-5.02-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Sophisticated graphical program which corrects your miss typing"
+HOMEPAGE="http://www.tkl.iis.u-tokyo.ac.jp/~toyoda/index_e.html https://github.com/mtoyoda/sl/"
+SRC_URI="https://github.com/mtoyoda/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Toyoda"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="l10n_ja"
+
+RDEPEND="sys-libs/ncurses:="
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+DOCS=( README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.02-LDFLAGS.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e \
+		"s/-lncurses/$($(tc-getPKG_CONFIG) --libs ncurses)/" \
+		Makefile || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin "${PN}"
+	doman "${PN}.1"
+
+	if use l10n_ja; then
+		newman "${PN}.1.ja" "${PN}.ja.1"
+		DOCS+=( README.ja.md )
+	fi
+
+	einstalldocs
+}