app-text/sigil: version bump to 0.9.13

Closes: https://bugs.gentoo.org/682700
Package-Manager: Portage-2.3.65, Repoman-2.3.12
Signed-off-by: Zamarin Arthur <arthurzam@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/11264
Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 98 insertions, 0 deletions

diff --git a/app-text/sigil/Manifest b/app-text/sigil/Manifest
index d56d7bc949b2..9a1989190d40 100644
--- a/app-text/sigil/Manifest
+++ b/app-text/sigil/Manifest
@@ -1 +1,2 @@
+DIST Sigil-0.9.13.tar.gz 18235134 BLAKE2B 4afe0f0258a8c1056029534ec696372e40343b9a398b612ee32fe95a3d417594bcc6782a4e6447323d67e84db5193756ff7c8756e160c432678ebc59ddeab706 SHA512 cafc6b075827239b73e80d3efa02e4e77d5903fed1faf8b600f70b178fb0c248c38d43e115f249124859edc12ddd8caf199ef0b0d05f20852eb060b27e5a3578
 DIST Sigil-0.9.8-Code.zip 19807795 BLAKE2B 002626842b2619b94889780a66e4de1f6d6fc9f07e36069608d2edae1078516d7c0fbedad6d4966f2cff64ccd21730719a04c144b3c3c1740ad727448aff8af2 SHA512 18cd137ead965bc97626499ec73dddb8db82b4d538c30f70e62546bd1eeb6e2e76ce7587d572354d973363a07e93ec33b60024bbef7914a22cbfc28a76af2a00
diff --git a/app-text/sigil/sigil-0.9.13.ebuild b/app-text/sigil/sigil-0.9.13.ebuild
new file mode 100644
index 000000000000..4fe858867563
--- /dev/null
+++ b/app-text/sigil/sigil-0.9.13.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit cmake-utils python-single-r1 readme.gentoo-r1 xdg-utils
+
+MY_P="Sigil-${PV}"
+
+DESCRIPTION="Sigil is a multi-platform WYSIWYG ebook editor for ePub format"
+HOMEPAGE="https://sigil-ebook.com/"
+SRC_URI="https://github.com/Sigil-Ebook/Sigil/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="GPL-3+ Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-text/hunspell:=
+	dev-libs/boost:=[threads]
+	dev-libs/libpcre:3=[pcre16]
+	dev-libs/mathjax
+	dev-libs/xerces-c[icu]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/cssselect[${PYTHON_USEDEP}]
+	dev-python/cssutils[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-qt/qtconcurrent-5.4:5
+	>=dev-qt/qtcore-5.4:5
+	>=dev-qt/qtgui-5.4:5
+	>=dev-qt/qtprintsupport-5.4:5
+	>=dev-qt/qtwebkit-5.4:5
+	>=dev-qt/qtwidgets-5.4:5
+	>=dev-qt/qtxmlpatterns-5.4:5
+	sys-libs/zlib[minizip]
+"
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( ChangeLog.txt README.md )
+
+DOC_CONTENTS="From Sigil's release notes:
+When you fire up Sigil for the very first time:
+navigate to the new General Preferences and select the default
+epub version you plan to work with (epub 2 or epub3) so that new
+empty ebooks start with the correct code.
+if you plan to work with epub3 epubs, you should change your
+PreserveEntities setting to use ONLY NUMERIC entities.
+
+For example use & # 1 6 0 ; for non-breaking spaces and etc.
+
+We strongly recommend enabling Mend On Open in your settings
+for best performance with Sigil."
+
+src_configure() {
+	python_export PYTHON_LIBPATH PYTHON_INCLUDEDIR
+	local mycmakeargs=(
+		-DINSTALL_BUNDLED_DICTS=0
+		-DMATHJAX_DIR="${EPREFIX}"/usr/share/mathjax
+		-DUSE_SYSTEM_LIBS=1
+		-DSYSTEM_LIBS_REQUIRED=1
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DPYTHON_LIBRARY="${PYTHON_LIBPATH}"
+		-DPYTHON_INCLUDE_DIR="${PYTHON_INCLUDEDIR}"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	python_fix_shebang "${ED}"/usr/share/sigil/
+	python_optimize "${ED}"/usr/share/sigil/
+	DISABLE_AUTOFORMATTING=true readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}