kde-frameworks/breeze-icons: 5.110.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 57 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index 72ed98e1d60b..c18331fa17ab 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1,2 +1,3 @@
 DIST breeze-icons-5.108.0.tar.xz 2172924 BLAKE2B 3a1d265e8e11df3048d18a806e145a46ef0f0a19ebc3d19e99f97da4d90211782715c9e9106814c8758dbbecbf8a448bcbc56d78c9636a58e201e11ac8820ecf SHA512 d540c938f4aae2d25074ce97ba9d3ec82514068192897bfa2c3387977778cac9e0753e182af6da4fefff5ff79bc68a71af6eaedbf37eba9c6392ccd0ba59612d
 DIST breeze-icons-5.109.0.tar.xz 2172836 BLAKE2B 6633fb5bee203bc9ddb3d20fc4c5fe1b40bba3dadc5bfe0fe8fa6f1ae571103cb53677092a755e5b69d38e9ea2e59e6d1345d3aadde35a9cfcf014c441920296 SHA512 e585f27d0c4a69f00d5645e6ce71a030972c3636cef8c3ab7376f2c44c6d237a41c8b0a46b9f1761cdeff67b347301db572efb6b8c9bfe371fd219b2af9738a6
+DIST breeze-icons-5.110.0.tar.xz 2173008 BLAKE2B 68c84b739228ad7ed91bcebcf10ec4402f36f70461449d85172e07d1c77923ae1a47c4dc6915c432230b0b7a936186454cfb94bf51af7393ec22302485b58000 SHA512 f13bde27c3da39c60dd3ec2e250eaefaa9fe29b01f740e87a0774d0717f95499b72c0fefed786f9ec66e7e31fd9d853837dd1e8ce300c4456d94ad8d56eb2321
diff --git a/kde-frameworks/breeze-icons/breeze-icons-5.110.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-5.110.0.ebuild
new file mode 100644
index 000000000000..64b8d6e11645
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-5.110.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake frameworks.kde.org python-any-r1 xdg-utils
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}