kde-frameworks/breeze-icons-rcc: 5.116.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 50 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons-rcc/Manifest b/kde-frameworks/breeze-icons-rcc/Manifest
index f43e5a7e9081..9ffa2719a7e3 100644
--- a/kde-frameworks/breeze-icons-rcc/Manifest
+++ b/kde-frameworks/breeze-icons-rcc/Manifest
@@ -1 +1,2 @@
 DIST breeze-icons-5.115.0.tar.xz 2173528 BLAKE2B 712c9cabb74bbdf9feb9a889fddda6ea654fd2a618f5c36a4aa782b5389032b829919ca5ef69a3310749ac10e2dc381700474d56e7cbc1478ae51030248d8789 SHA512 f4b5f54bb80dcd2bba6edd02a412eb675b02d438ba0ee82d6dc4eaac1ed2aceb11b46ce143bbe825c26f823d5b897619e02c26b23addf2de05830a320dd124f8
+DIST breeze-icons-5.116.0.tar.xz 2173596 BLAKE2B 238d05983fc473771802b1537d73b51d5f6fb2936635cc8ad3e4162166a0ac9d0f5ae66b9fb28b6e3d2f168ff1fbcf3bc1f4a993687520766fa1f682c413a07a SHA512 3b65bd712262eb4aa0e3760d963b5ad480d840bb680ed7516b69d0d0fb6ad52dffe7c81ec2535adb36a34ec00154253570e5da8f97ef7d4d235ef0e9723751b8
diff --git a/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.116.0.ebuild b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.116.0.ebuild
new file mode 100644
index 000000000000..d295e2ea983f
--- /dev/null
+++ b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.116.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="breeze-icons"
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Breeze SVG icon theme binary resource"
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:0
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=ON
+		-DSKIP_INSTALL_ICONS=ON
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# provided by kde-frameworks/breeze-icons
+	rm -rv "${ED}"/usr/$(get_libdir)/cmake/KF5BreezeIcons || die
+}