games-engines/exult: extra ebuild changes/updates

bit of tidying and:
* use EPREFIX
* use html/ for for docs
* add joystick on libSDL2
* depend on xorg-proto, fails without because of libsdl2
 (and keep X on libsdl2, seems needed)
* drop virtual/opengl, this doesn't use GL anymore I can see?
  also does not seem to need libsdl2[opengl]

Probably other improvements that could be done (better way or
instructions to find game data in $HOME rather than /usr/share,
and have not looked at gtk+exult-studio), but left alone for now.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 26 insertions, 25 deletions

diff --git a/games-engines/exult/exult-1.8.ebuild b/games-engines/exult/exult-1.8.ebuild
index 0b544c3211fb..bf03c5b70837 100644
--- a/games-engines/exult/exult-1.8.ebuild
+++ b/games-engines/exult/exult-1.8.ebuild
@@ -5,52 +5,53 @@ EAPI=8
 
 inherit autotools
 
-DESCRIPTION="an Ultima 7 game engine that runs on modern operating systems"
-HOMEPAGE="http://exult.sourceforge.net/"
-SRC_URI="https://downloads.sourceforge.net/${PN}/exult-all-versions/${PV}/${P}.tar.gz"
+DESCRIPTION="Ultima 7 game engine that runs on modern operating systems"
+HOMEPAGE="https://exult.sourceforge.net/"
+SRC_URI="mirror://sourceforge/exult/exult-all-versions/${PV}/${P}.tar.gz"
 
 LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
 IUSE="alsa fluidsynth timidity tools"
 
-DEPEND="
+RDEPEND="
 	games-misc/exult-sound
-	>=media-libs/libpng-1.6:0=
+	media-libs/libpng:=
+	media-libs/libsdl2[X,joystick,sound,video]
 	media-libs/libvorbis
 	sys-libs/zlib:=
-	virtual/opengl
 	alsa? ( media-libs/alsa-lib )
-	fluidsynth? ( media-sound/fluidsynth )
-	media-libs/libsdl2[sound,video,X]
-	timidity? ( >=media-sound/timidity++-2 )
-"
-RDEPEND="${DEPEND}"
-
-DOCS=(
-	AUTHORS ChangeLog FAQ NEWS README
-)
+	fluidsynth? ( media-sound/fluidsynth:= )
+	timidity? ( media-sound/timidity++ )"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto"
 
 src_prepare() {
 	default
+
 	eautoreconf
 }
 
 src_configure() {
-	econf \
-		--enable-zip-support \
-		--with-desktopdir=/usr/share/applications \
-		--with-icondir=/usr/share/pixmaps \
-		$(use_enable alsa) \
-		$(use_enable fluidsynth) \
-		$(use_enable timidity timidity-midi) \
-		$(use_enable tools) \
-		$(use_enable tools compiler) \
+	local econfargs=(
+		--docdir="${EPREFIX}"/usr/share/${PF}/html
+		--with-desktopdir="${EPREFIX}"/usr/share/applications
+		--with-icondir="${EPREFIX}"/usr/share/pixmaps
+		$(use_enable alsa)
+		$(use_enable fluidsynth)
+		$(use_enable timidity timidity-midi)
+		$(use_enable tools)
+		$(use_enable tools compiler)
 		$(use_enable tools mods)
+		--enable-zip-support
+	)
+
+	econf "${econfargs[@]}"
 }
 
 pkg_postinst() {
 	elog "You *must* have the original Ultima7 The Black Gate and/or"
 	elog "The Serpent Isle installed."
-	elog "See documentation in /usr/share/doc/${PF} for information."
+	elog "See documentation in ${EROOT}/usr/share/doc/${PF} for information."
 }