dev-python/pydevd: properly recompile pre-built file

Bug: https://bugs.gentoo.org/812041
Closes: https://bugs.gentoo.org/812386
Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

2 files changed, 80 insertions, 60 deletions

diff --git a/dev-python/pydevd/pydevd-2.5.0-r1.ebuild b/dev-python/pydevd/pydevd-2.5.0-r1.ebuild
new file mode 100644
index 000000000000..699432597995
--- /dev/null
+++ b/dev-python/pydevd/pydevd-2.5.0-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
+HOMEPAGE="https://github.com/fabioz/PyDev.Debugger/"
+SRC_URI="https://github.com/fabioz/PyDev.Debugger/archive/refs/tags/pydev_debugger_${PV//./_}.tar.gz"
+S="${WORKDIR}/PyDev.Debugger-pydev_debugger_${PV//./_}"
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# After removing and recompiling the prebuilt lib the tests fail?
+# For some reason the test suite is executing a slightly different gdb command
+# then before, which is lacking the file name of the lib that was pre built:
+# gdb: No symbol table is loaded. Use the "file" command
+# This also happens outside of portage so it is not related to any *FLAGS
+RESTRICT="test"
+
+BDEPEND="
+	test? (
+		dev-python/untangle[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+# Block against the version of debugpy that still bundles pydevd
+RDEPEND="
+	!<dev-python/debugpy-1.4.2
+	sys-devel/gdb
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# Clean up some prebuilt files
+	rm -r third_party || die
+	cd pydevd_attach_to_process || die
+
+	# Remove these Windows files
+	rm attach_{amd64,x86}.dll || die
+	rm inject_dll_{amd64,x86}.exe || die
+	rm run_code_on_dllmain_{amd64,x86}.dll || die
+	rm -r windows winappdbg || die
+
+	# Remove these MacOS files
+	rm attach_x86_64.dylib || die
+
+	# Remove these prebuilt linux files
+	rm attach_linux_{amd64,x86}.so || die
+
+	cd linux_and_mac || die
+	rm compile_mac.sh || die
+}
+
+src_compile() {
+	pushd pydevd_attach_to_process/linux_and_mac || die
+	# recompile removed file (extracted from compile_linux.sh)
+	$(tc-getBUILD_CXX) ${CXXFLAGS} ${CFLAGS} -o "attach_linux_${ARCH}.so" \
+		-ldl ${LDFLAGS} -nostartfiles attach.cpp || die
+	mv "attach_linux_${ARCH}.so" ../ || die
+	popd || die
+	python_foreach_impl distutils-r1_python_compile
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# Remove this duplicate that is installed directly to /usr/
+	# These files are also correctly installed to the python site-packages dir
+	rm -r "${ED}/usr/pydevd_attach_to_process" || die
+}
diff --git a/dev-python/pydevd/pydevd-2.5.0.ebuild b/dev-python/pydevd/pydevd-2.5.0.ebuild
deleted file mode 100644
index d473a0616068..000000000000
--- a/dev-python/pydevd/pydevd-2.5.0.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..9} )
-
-inherit distutils-r1
-
-DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
-HOMEPAGE="https://github.com/fabioz/PyDev.Debugger/"
-SRC_URI="https://github.com/fabioz/PyDev.Debugger/archive/refs/tags/pydev_debugger_${PV//./_}.tar.gz"
-S="${WORKDIR}/PyDev.Debugger-pydev_debugger_${PV//./_}"
-
-LICENSE="EPL-1.0"
-SLOT="0"
-KEYWORDS="~amd64"
-
-BDEPEND="
-	test? (
-		dev-python/untangle[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-		sys-devel/gdb
-	)
-"
-
-distutils_enable_tests pytest
-
-# These files are included pre-built in the sources
-# TODO: Investigate what this is and if/how we can compile this properly
-QA_PREBUILT="
-	/usr/lib/python*/site-packages/pydevd_attach_to_process/attach_linux_*.so
-"
-
-python_prepare_all() {
-	# AssertionError: TimeoutError (note: error trying to dump threads on timeout).
-	# TODO: investigate and fix this
-	sed -i \
-		-e 's:test_case_qthread4:_&:' \
-		-e 's:test_path_translation:_&:' \
-		-e 's:test_asyncio_step_over_basic:_&:' \
-		-e 's:test_asyncio_step_over_end_of_function:_&:' \
-		-e 's:test_asyncio_step_in:_&:' \
-		-e 's:test_asyncio_step_return:_&:' \
-		tests_python/test_debugger.py || die
-	sed -i \
-		-e 's:test_evaluate_exception_trace:_&:' \
-		-e 's:test_path_translation_and_source_reference:_&:' \
-		tests_python/test_debugger_json.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	# Remove this duplicate that is installed directly to /usr/
-	# These files are also correctly installed to the python site-packages dir
-	rm -r "${ED}/usr/pydevd_attach_to_process"
-}