dev-python/django: Bump to 3.0.12

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 5863a878b886..bdbcbcd07137 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -2,6 +2,8 @@ DIST Django-2.2.17.checksum.txt 2438 BLAKE2B 5d9454884110f1debec7fa1644b13be43b9
 DIST Django-2.2.17.tar.gz 8885492 BLAKE2B 30046adc54c31e0e8dac3c573da58e8536246ba6fc5675ec5ad5efc4b170331b893ffe766e7eb404b445d5b37e018e1ac9e2b8e659a5f10c4c165ec9ef5c00d1 SHA512 4ba1e12332cafaa49a087494f9e85e992a414ad153ef935fcf50f1a533ac9c7049a421140552f77b3dbf41c51a4f42aca13dc5f8f479049c21037c541a34320b
 DIST Django-3.0.11.checksum.txt 2438 BLAKE2B df936992a02e5a34b26e91654962507d973f8831c1eebada4cbdb578f83fba974532867b9f20828afc2467c2521e117b8dd543cde6f664d3c122a95207c50608 SHA512 a7b98d102775cc7854b0c242507d4ff8778984dc8b2e269352103249d6d1c5cea7e6eb8dbe08700b19ad4428e30c469e0e959a622ea4ce3198a75f72b2bb8871
 DIST Django-3.0.11.tar.gz 8958879 BLAKE2B 078ffde9ae186ae8add2136c303ba38a1b38525481b2272384b8a1bb3428dcf6a31991a86b2078aea6cf250808af399acac5461a33c8e1fda5d6bc552eac478f SHA512 d24e8167f3f871f24ea5e288557a49d71f9b5c398c84e8434d5d3dc224ef62775121a016ad89e997fabe88893adc3a83176211d5b9a9730ec23d37d256aa4fb0
+DIST Django-3.0.12.checksum.txt 2556 BLAKE2B 9012a130029c6fe73ace78fbdd32f1653bb7a7e84c343c394acc5563b7de9b5d6ec58734fdf79f2e7657f18644dd3a12c12c4a400a1002ad74d0891738ef4137 SHA512 46e7291f4d73472a118ff3aca4f597d6abde4a4217bb95ed84fda91efd0ed63e946d9ddf35ae65ff1e898462aebc32a3a43241f261099b17667958412d5afb32
+DIST Django-3.0.12.tar.gz 9255277 BLAKE2B 68be34ddad965bacca6bfcf045b5ab4072ef8a17f09acc674d2b5535b074d90c6881fd22edd89bdc82eefc90a2e7f561a041f9da066b85c13b10866f731a6106 SHA512 7f21a1a88a8c57d3b6ffa1a39e0df491e45f4e37181c4951db2a330266bf3ed8bf4e240a69a9b627dbbb090816c991b877b777e35b1c252a5ee08680eb3b0135
 DIST Django-3.1.4.checksum.txt 2466 BLAKE2B 635ddd40b542890aef29f53df0fad172e48450081f57c72042a71bb5de654b1d1f5f7ce0c588b1070a203e1d4afe3a1ed19431dd23a2a67cd510d4072c79a00f SHA512 729b771008489bbf0563002e438ef88abb2a14b2c29f307cb2db9c75450f30ac8bd4920bf0493dbec06b3640fc0d4b6817e8a054af1028ad065bd321c761a6c3
 DIST Django-3.1.4.tar.gz 9392125 BLAKE2B b583442de50c358e70a49b9ef557d43211e6faee17933a44012dbb9f0dac3ccbf0a91e01a2b8b798fff7ae05100199e9e9c94a81748b41ea13e49d12bb510617 SHA512 02cfaabb25e5f932dcbf659faba2f0afe298e4bee4f510f7adebfff181bdd13c3a0b08e8ce379bcc59326d904be8699db4ce31065d93566b93cad758365207f5
 DIST Django-3.1.5.checksum.txt 2428 BLAKE2B 69347177b3c8c592a0b9df832c8f0abebdd4f1ff420f95f63310eb41d3614b241dc8f01b71abfec12faa006a8e69310d31cd68425f57ecf7a02948e83c65e0b3 SHA512 93d3e0de057518b60d9da2c1193ec59a8601f53b5d81a09fa4f6866336fbff85b81c01711eb07544fce30fe17e6dec89e5a5d6a66a929d451bca77cfe172bf19
diff --git a/dev-python/django/django-3.0.12.ebuild b/dev-python/django/django-3.0.12.ebuild
new file mode 100644
index 000000000000..c5e25f2be57a
--- /dev/null
+++ b/dev-python/django/django-3.0.12.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/asgiref[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( app-crypt/openpgp-keys-django )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.6-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	# do not bind to a specific version
+	# https://bugs.gentoo.org/750695
+	sed -i -e 's:asgiref ~= 3.2:asgiref:' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Additional Backend support can be enabled via"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	elog
+	elog "Other features can be enhanced by"
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}