dev-util/blueprint-compiler: new package; add 0.6.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

3 files changed, 86 insertions, 0 deletions

diff --git a/dev-util/blueprint-compiler/Manifest b/dev-util/blueprint-compiler/Manifest
new file mode 100644
index 000000000000..0abec39801bf
--- /dev/null
+++ b/dev-util/blueprint-compiler/Manifest
@@ -0,0 +1 @@
+DIST blueprint-compiler-v0.6.0.tar.bz2 56896 BLAKE2B 318ffa52b2fbf3b07058e5b4d2f9bb0ef1f6614586b79968889921964b454e5c26d44e58a18185263797f7569135662d14471bafd8e501d7c6386e88972193d0 SHA512 458016f4eabef15026cb3ee675111984b19af8a9139bc412dfb48dfef56b0d0ff028316001d0ce04a90b50d6785c92d799f17ed42ca53fc7582345729ae02207
diff --git a/dev-util/blueprint-compiler/blueprint-compiler-0.6.0.ebuild b/dev-util/blueprint-compiler/blueprint-compiler-0.6.0.ebuild
new file mode 100644
index 000000000000..b54ac7882f03
--- /dev/null
+++ b/dev-util/blueprint-compiler/blueprint-compiler-0.6.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit meson python-single-r1
+
+DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
+HOMEPAGE="https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/
+	https://gitlab.gnome.org/jwestman/blueprint-compiler/"
+
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/jwestman/${PN}.git"
+else
+	SRC_URI="https://gitlab.gnome.org/jwestman/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	S="${WORKDIR}"/${PN}-v${PV}
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0"
+IUSE="doc test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}"
+BDEPEND="
+	${RDEPEND}
+	doc? (
+		$(python_gen_cond_dep '
+			dev-python/furo[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		gui-libs/gtk:4[introspection]
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+DOCS=( CONTRIBUTING.md MAINTENANCE.md NEWS.md README.md )
+
+src_configure() {
+	local -a emesonargs=(
+		$(meson_use doc docs)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+
+	use doc && build_sphinx docs
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
diff --git a/dev-util/blueprint-compiler/metadata.xml b/dev-util/blueprint-compiler/metadata.xml
new file mode 100644
index 000000000000..c28d6bd1544b
--- /dev/null
+++ b/dev-util/blueprint-compiler/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="person">
+    <email>xgqt@gentoo.org</email>
+    <name>Maciej Barć</name>
+  </maintainer>
+  <longdescription>
+    Blueprint helps you build user interfaces in GTK quickly and declaratively.
+    It has modern IDE features like code completion and hover documentation,
+    and the compiler points out mistakes early on so you can focus on making
+    your app look amazing.
+  </longdescription>
+  <upstream>
+    <changelog>https://gitlab.gnome.org/jwestman/blueprint-compiler/-/raw/main/NEWS.md</changelog>
+    <doc>https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/</doc>
+    <bugs-to>https://github.com/jwestman/blueprint-compiler/issues</bugs-to>
+    <remote-id type="gnome-gitlab">jwestman/blueprint-compiler</remote-id>
+  </upstream>
+</pkgmetadata>