x11-misc/meteo: Use ayatana indicators

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/x11-misc/meteo/meteo-0.9.9.1-r1.ebuild b/x11-misc/meteo/meteo-0.9.9.1-r1.ebuild
new file mode 100644
index 000000000000..b68fc55cee62
--- /dev/null
+++ b/x11-misc/meteo/meteo-0.9.9.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Forecast application using OpenWeatherMap API"
+HOMEPAGE="https://gitlab.com/bitseater/meteo"
+SRC_URI="https://gitlab.com/bitseater/meteo/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	$(vala_depend)
+	dev-libs/libayatana-appindicator:0
+	dev-libs/glib:2
+	dev-libs/json-glib
+	net-libs/libsoup:2.4
+	net-libs/webkit-gtk:4
+	x11-libs/gtk+:3
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+	x11-themes/hicolor-icon-theme
+"
+BDEPEND="${PYTHON_DEPS}
+	dev-libs/appstream-glib
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+# One test needs network (#828052), the other simply checks desktop file
+# validation, that we also test with our QA tests
+RESTRICT="test"
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_install() {
+	meson_src_install
+	dosym com.gitlab.bitseater.meteo /usr/bin/meteo
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}