media-fonts/noto-emoji: Drop buildfont option

As talked with Michał, this option is getting harder to maintain everyday due
to the growing amount of deps being needed and they being hard to maintain.

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 52 insertions, 0 deletions

diff --git a/media-fonts/noto-emoji/metadata.xml b/media-fonts/noto-emoji/metadata.xml
index 1f615adf787d..a1229f4979e4 100644
--- a/media-fonts/noto-emoji/metadata.xml
+++ b/media-fonts/noto-emoji/metadata.xml
@@ -7,6 +7,7 @@
 	</maintainer>
 	<use>
 		<flag name="buildfont">Build Noto Emoji font with supplied images</flag>
+		<flag name="icons">Install Noto Emoji icon theme</flag>
 	</use>
 	<upstream>
 		<remote-id type="github">googlefonts/noto-emoji</remote-id>
diff --git a/media-fonts/noto-emoji/noto-emoji-20220912-r1.ebuild b/media-fonts/noto-emoji/noto-emoji-20220912-r1.ebuild
new file mode 100644
index 000000000000..6499e36b1e77
--- /dev/null
+++ b/media-fonts/noto-emoji/noto-emoji-20220912-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit font
+
+DESCRIPTION="Google Noto Emoji fonts"
+HOMEPAGE="https://www.google.com/get/noto/ https://github.com/googlefonts/noto-emoji"
+
+COMMIT="e8073ab740292f8d5f19b5de144087ac58044d06"
+SRC_URI="https://github.com/googlefonts/noto-emoji/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="icons"
+
+RESTRICT="binchecks strip"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+src_prepare() {
+	default
+
+	# Drop font for Windows 10
+	rm fonts/NotoColorEmoji_WindowsCompatible.ttf || die
+}
+
+src_compile() { :; }
+
+src_install() {
+	FONT_S="${S}/fonts"
+	# Drop non used fonts
+	rm -f fonts/*COLR*.ttf || die
+
+	# Don't lose fancy emoji icons
+	if use icons; then
+		for i in 32 72 128 512; do
+			insinto "/usr/share/icons/${PN}/${i}/emotes/"
+			doins png/"${i}"/*.png
+		done
+
+		insinto /usr/share/icons/"${PN}"/scalable/emotes/
+		doins svg/*.svg
+	fi
+
+	FONT_SUFFIX="ttf"
+	font_src_install
+
+	dodoc README.md
+}