app-text/pelican: 4.9.1

Signed-off-by: Sebastian Pipping <sping@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/app-text/pelican/Manifest b/app-text/pelican/Manifest
index 271058b778e8..5d37f3e38a90 100644
--- a/app-text/pelican/Manifest
+++ b/app-text/pelican/Manifest
@@ -1,2 +1,3 @@
 DIST pelican-4.8.0.gh.tar.gz 1401791 BLAKE2B 889c9054659c9f98cca571fa0f3ea9ee7752aa65c3feb71278570bad74095f521d3838aa1a32dc3ae331ba86149cdd10be9c31c7ed5bc6e06348edf3eb3bb081 SHA512 2e94eb88a836bcb430026463c0e7e906b7f065507e0d873b6e0fc980e271e6a8f2e62b22af4b61c963d90ef61d57787de20656fe7497b0ae14e93eff2d364f3b
 DIST pelican-4.9.0.gh.tar.gz 1374399 BLAKE2B 2fa91ff9b5ddacac1fd64d9325ccb1fadb9bbfaa9c6098920a43a576f3d8d7be31a98b5250b2ea10bee63993d8b9bb72fdebdf9d57d0518d1f4bddef705e2804 SHA512 a50d0fbad816fa4a73eb94d0aa15cf5f9321ed2bdb50addbebbf0024f2fc7fd73ab94b314b5821068d552dcd1b11a54ca6511117aac732340156f2361a7e832c
+DIST pelican-4.9.1.gh.tar.gz 1374443 BLAKE2B d9dfa234b0f19cd02ccc8867e5b4f6e0444300692d69001baf23943230f27f8a7bc91e98e5c4c3cd194abadf8fb140c0e1a0c3beb39e5d288113ecc4e487c6a6 SHA512 70b7efd7a38dc2069b1eb9141647fa80bf959de36936ad7b4d38407be7e029fc788ef9b9f297d99e5dc6cad67d58fe6ff97f9b542db7e0a9c23e2907d4604e21
diff --git a/app-text/pelican/pelican-4.9.1.ebuild b/app-text/pelican/pelican-4.9.1.ebuild
new file mode 100644
index 000000000000..a8ec456458a6
--- /dev/null
+++ b/app-text/pelican/pelican-4.9.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A tool to generate a static blog, with restructured text or markdown input files"
+HOMEPAGE="
+	https://getpelican.com/
+	https://pypi.org/project/pelican/
+"
+SRC_URI="
+	https://github.com/getpelican/pelican/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="doc examples markdown"
+
+RDEPEND="
+	>=dev-python/docutils-0.20.1[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/feedgenerator-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.1.2[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.16.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+	>=dev-python/rich-13.6.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-1.3.7[${PYTHON_USEDEP}]
+	>=dev-python/watchfiles-0.21.0[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	markdown? ( >=dev-python/markdown-3.1[${PYTHON_USEDEP}] )"
+BDEPEND="
+	test? (
+		>=dev-python/markdown-3.1[${PYTHON_USEDEP}]
+		dev-python/typogrify[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( README.rst )
+
+EPYTEST_DESELECT=(
+	# Needs investigation, we weren't running tests at all before
+	pelican/tests/test_testsuite.py::TestSuiteTest::test_error_on_warning
+	pelican/tests/test_pelican.py::TestPelican::test_basic_generation_works
+	pelican/tests/test_pelican.py::TestPelican::test_custom_generation_works
+)
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	if use examples; then
+		docinto /usr/share/doc/${PF}
+		docompress -x /usr/share/doc/${PF}/samples
+		dodoc -r samples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Typographical enhancements (alternative to markdown)" dev-python/typogrify
+}