kde-frameworks/breeze-icons: 5.113.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 57 insertions, 0 deletions

diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index 2fb6508fa485..3c4e0ceb0844 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1 +1,2 @@
 DIST breeze-icons-5.112.0.tar.xz 2172852 BLAKE2B 0b00973c6d8fbb9aa42b8f3f7b4143b26d878f5f9e53444d021d1e6fa0f17490ceea93a2ae5608700d70f00f66842f58b00bb876a32c032dd9dadf6f0633121a SHA512 7773d209b3b6a5c2d1ebc8be4cfb53fe443245c6baab0af65999903b4c29a36677a0b4215ed59ddf8ffb607d08f1fe354cd723ba95b8ee4f610da8d33ede214d
+DIST breeze-icons-5.113.0.tar.xz 2173152 BLAKE2B e34582879fdcbcd620aac9cbe627e623b212f6a3fe9684fe82386319cdc33b039cae5fe7119ba18cadf33a4e0008b8268bb3ba303106908e910213ba98ce1698 SHA512 deb5f824fc9613a9e46fd2bfc048901c7b34ae364e566f406fc1316a01a1942385845f6127827032a5785b30d2e3c6e37b8185f891911401629dd27dcb8b15d5
diff --git a/kde-frameworks/breeze-icons/breeze-icons-5.113.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-5.113.0.ebuild
new file mode 100644
index 000000000000..311dffe986e2
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-5.113.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake frameworks.kde.org python-any-r1 xdg-utils
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:0
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}