media-sound/easyeffects: add 7.1.3

Got tired of waiting for lsp-plugins in the tree to be updated and while
upstream recommends >=1.2.10, 1.2.6 seems to work for now.

Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/media-sound/easyeffects/Manifest b/media-sound/easyeffects/Manifest
index d50734980def..3673ff569887 100644
--- a/media-sound/easyeffects/Manifest
+++ b/media-sound/easyeffects/Manifest
@@ -1 +1,2 @@
 DIST easyeffects-7.0.7.tar.gz 3359508 BLAKE2B 16c4fd322eefcd16bb8a83a5443e482689b2f4665556f306e11c072b869f9929d5c7b781f7adbba7faacb71a07c0bdd2b61efb6584131e61e2bfa6dedcdf3c8d SHA512 3ceadf6c8acff64a98cf6c0e2c5386aa7b6d4649d49a9879574415bb7959b9c7243870bc30ea38bb3de3ee5b4d9ab9892eb8809069c08b2a50ab7f2342f6a1e4
+DIST easyeffects-7.1.3.tar.gz 3426093 BLAKE2B 62ff40388df2a3452d23968881ab7d247c5504abc4524564e919cc520700e64978914248f00fb8b3ae251b895850d9a4dee763576baf2c43af3cd1105d2b62d5 SHA512 9e277b0c432f5015b33d4ac6961d5eec4cbf498dd2e947d231a9c13d8c7b7680f7ded7bf3d55d2c72ebf46de94308447a0b1e3b8cbbb13ce96c3a79bf027ffa3
diff --git a/media-sound/easyeffects/easyeffects-7.1.3.ebuild b/media-sound/easyeffects/easyeffects-7.1.3.ebuild
new file mode 100644
index 000000000000..d3af93f6daff
--- /dev/null
+++ b/media-sound/easyeffects/easyeffects-7.1.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson toolchain-funcs
+
+DESCRIPTION="Limiter, auto volume and many other plugins for PipeWire applications"
+HOMEPAGE="https://github.com/wwmm/easyeffects"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/wwmm/easyeffects"
+else
+	SRC_URI="https://github.com/wwmm/easyeffects/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="calf +doc mda-lv2 zamaudio"
+
+# Reminder: since 7.0.8 upstream recommends >=>=media-libs/lsp-plugins-1.2.10
+# but as of late December 2023, the tree remains stuck at 1.2.6.
+# Update the dependency when possible (Bug #915777).
+COMMON="dev-cpp/nlohmann_json
+	dev-cpp/tbb
+	>=dev-libs/glib-2.56:2
+	dev-libs/libfmt
+	>=dev-libs/libsigc++-3.0.6:3
+	>=gui-libs/gtk-4.10.0:4
+	>=gui-libs/libadwaita-1.2.0:1
+	media-libs/libbs2b
+	>=media-libs/libebur128-1.2.0
+	media-libs/libsndfile
+	media-libs/libsoundtouch
+	>=media-libs/lilv-0.22
+	>=media-libs/lv2-1.18.2
+	media-libs/rnnoise
+	media-libs/speexdsp
+	>=media-libs/zita-convolver-3.0.0
+	>=media-video/pipewire-0.3.41
+	sci-libs/gsl:=
+	sci-libs/fftw:3.0"
+# Only header files are used from these two
+DEPEND="${COMMON}
+	media-libs/ladspa-sdk
+	media-libs/libsamplerate"
+RDEPEND="${COMMON}
+	>=media-libs/lsp-plugins-1.2.6[lv2]
+	sys-apps/dbus
+	calf? ( >=media-plugins/calf-0.90.1[lv2] )
+	doc? ( gnome-extra/yelp )
+	mda-lv2? ( media-plugins/mda-lv2 )
+	zamaudio? ( media-plugins/zam-plugins )"
+BDEPEND="dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != "binary" ]] ; then
+		if ! tc-is-gcc; then
+			if ! tc-is-clang || [[ $(clang-major-version) -lt 16 ]]; then
+				die "${PN} can only be built with GCC or >=Clang-16 due to required level of C++20 support"
+			fi
+		elif [[ $(gcc-major-version) -lt 11 ]] ; then
+			die "Since version 6.2.5 ${PN} requires GCC 11 or newer to build (Bug #848072)"
+		fi
+	fi
+}
+
+pkg_postinst() {
+	gnome2_gconf_install
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_gconf_uninstall
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}