gnome-extra/evolution-ews: bump to 3.34.4

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 66 insertions, 0 deletions

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index c03afe7240c1..1f62a0097c55 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -1 +1,2 @@
 DIST evolution-ews-3.32.2.tar.xz 534056 BLAKE2B 2f935910cba44d69b2d8bcc3021709502c1a129ef29d18a847bccd14837d0c18c9700a97f978decb36f9c28242df81a9021dfc536e31f3d8f7793a0dc4c6b680 SHA512 5696ea660d0b52c0083664ad203eaed372fb9653399152ccbca0f6360a3e0c4503b5dacf4f9bf5650b1b64696c0fe06e2383bb408bed604ea0312660b4639388
+DIST evolution-ews-3.34.4.tar.xz 538964 BLAKE2B 3b23dee72b13bd7da0efdacc13bf16052b52287dfbdeb913100244cfbdc726fdd6dc526fa38eb3da849ea5e9c95e9bb59fedadbe0238c37698cedefdda05f82d SHA512 397dd89c81c986501aaf5c0460735577ebe2aa0bfe549359073e211e912e3622c7ba61eb90898ec00a06bb1c4d02a565446a3b0620ff8515088d706d5c246c91
diff --git a/gnome-extra/evolution-ews/evolution-ews-3.34.4.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.34.4.ebuild
new file mode 100644
index 000000000000..775b146c143b
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.34.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.46:2
+	>=dev-libs/libical-3.0.5:0=[introspection]
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-2.58:2.4
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	test? ( net-libs/uhttpmock )
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake-utils_src_prepare call, if that works
+src_prepare() {
+	cmake-utils_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_test() {
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+}