dev-lang/qore: new package; 1.19.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

3 files changed, 96 insertions, 0 deletions

diff --git a/dev-lang/qore/Manifest b/dev-lang/qore/Manifest
new file mode 100644
index 000000000000..ff5dbf68371b
--- /dev/null
+++ b/dev-lang/qore/Manifest
@@ -0,0 +1 @@
+DIST qore-1.19.0.tar.gz 3932880 BLAKE2B 8987a818e4fef495d9e07477715f18ad70541c81108bbc3aac56660e4d2ee9349303654ba07a849a7bfb43952d0ee8b868224f029254c83f435aa024def08669 SHA512 5264db098644ba39316e7825f1ed8243240c506a22c15836fcfa9500b173807ee9c4d213577d3a9eee7220d5d15ad171f05f75a431fb0537c95ab3dc761cbba3
diff --git a/dev-lang/qore/metadata.xml b/dev-lang/qore/metadata.xml
new file mode 100644
index 000000000000..f623d113a866
--- /dev/null
+++ b/dev-lang/qore/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="person">
+    <email>xgqt@gentoo.org</email>
+    <name>Maciej Barć</name>
+  </maintainer>
+  <longdescription>
+    The Qore programming language is a powerful, thread-capable, embeddable
+    weakly-typed language with optional strong typing and procedural and
+    object-oriented features designed for anything from quick scripting to
+    complex multithreaded, network-aware application development to embedded
+    application scripting. Qore was initially designed to facilitate the rapid
+    implementation of sophisticated interfaces in embedded code in an
+    enterprise environment, and has since grown into a general-purpose language
+    as well.
+  </longdescription>
+  <upstream>
+    <bugs-to>https://github.com/qorelanguage/qore/issues</bugs-to>
+    <remote-id type="github">qorelanguage/qore</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-lang/qore/qore-1.19.0.ebuild b/dev-lang/qore/qore-1.19.0.ebuild
new file mode 100644
index 000000000000..5ca2ae1bc341
--- /dev/null
+++ b/dev-lang/qore/qore-1.19.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Qore, the embeddable multithreaded scripting language"
+HOMEPAGE="http://qore.org/
+	https://github.com/qorelanguage/qore/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/qorelanguage/${PN}.git"
+else
+	SRC_URI="https://github.com/qorelanguage/${PN}/archive/release-${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-release-${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+	app-arch/bzip2:=
+	dev-libs/libpcre:=
+	dev-libs/mpfr:=
+	dev-libs/openssl:=
+	sys-libs/zlib:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local -a myconf=(
+		--disable-optimization
+		--disable-profile
+		--disable-static-bz2
+		--disable-static-common
+		--disable-static-openssl
+		--disable-static-pcre
+		--disable-static-zlib
+		$(use_enable debug)
+	)
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	PATH="${S}:${PATH}" emake check
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name "*.la" -delete ||
+		die "failed to remove libtool files without corresponding static libraries"
+}