sys-kernel/gentoo-kernel-bin: add 5.4.145-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 9f8e9f8fa186..feff7759f608 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -64,6 +64,7 @@ DIST gentoo-kernel-5.4.144-1.amd64.xpak 61366776 BLAKE2B 24745e27ead7e35eab3cbf2
 DIST gentoo-kernel-5.4.144-1.arm64-r1.xpak 57983262 BLAKE2B 473427e2370a3e05fabf0a4364c3e9946322d0340c7ac1335184aa737cc5476147a95c14fa9c1cc36e60ab4420f7dc0df85d99576ff88d7a6647094fe29af3a6 SHA512 7001a486a41c2d18f899b64f9b75d1d7e4b9fe202af07099fe9523122c05620c00bfb66d253457e8c5e6417f7885ebdefc78df9ffeecf2ff2fbf8aa76926493f
 DIST gentoo-kernel-5.4.144-1.x86.xpak 53171435 BLAKE2B 188f4ca01ebec91a21c3bc4f6d5f3c65ae84c97b06e077f9b2f75d070b50d92d91a3586783b65b72097b03d7d4cace451e51592fd970126bfb77e7fcc34becad SHA512 5f6536748b67944e007b0f84cfa493cfa70159a134840962db92cd092c15a29a0116b64011b932871909055b11dd6b693a61c4c2210a9ab97041ff396219b93f
 DIST gentoo-kernel-5.4.145-1.amd64.xpak 61377390 BLAKE2B c71ec75baee907bd2f760c1d0f745b4dd7b7b3cb45080cb596aadb35e618689a3f11b607f8c219b330fabf2f13e1d1de47fd50a838ba897ae0cb2efdc66aa9d8 SHA512 db1625a4e2e975c23f99c53363ecb0eec07c0b1d4c85fa2532645e1cfcc05ab82f2f262733666fb9472d823fd3fc9d250aef0256924afde61362bc74a229940f
+DIST gentoo-kernel-5.4.145-1.arm64-r1.xpak 58052696 BLAKE2B d6307dd64cd4bac6e3ffb2f1e0b79c7db918f9be926bd36cdacb06263efe8cc203b36bde8c5d5b93b38d673f60fce29121215099bde5a0663b89461927b9e706 SHA512 17a1fb9f4c44ca367ca6b5979dad4df8f26a09cd4292818c882c91b52a90761ecc711741d7969792fad691944ee961b0dd1517679ddd6dc7d1da10d81b52470d
 DIST gentoo-kernel-5.4.145-1.x86.xpak 53156535 BLAKE2B dedace8aead3af364d179d46cf653dd64f374b8a17df5d10ce36a058772838fad613352ac24ace3d0a6395b04c7d1aac5ef8a6ef8267fa363c74ec64dcddbdbb SHA512 1b44642b642645902fe8614fd1856fbc8d97bf7d05a2d3586d4ee60a662febdfc87952fe5b430eda7b92891a6d63237de5c944b253fa9c2e7a2661b98e6d393f
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.145-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.145-r1.ebuild
new file mode 100644
index 000000000000..3b97f74d1041
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.145-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64-r1.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}