dev-qt/qtcore: Drop 5.15.2-r13

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 105 deletions

diff --git a/dev-qt/qtcore/Manifest b/dev-qt/qtcore/Manifest
index 5e69125c6d40..9408a916e7bf 100644
--- a/dev-qt/qtcore/Manifest
+++ b/dev-qt/qtcore/Manifest
@@ -1,3 +1,2 @@
-DIST qtbase-5.15.2-38ad2f39.tar.gz 67969272 BLAKE2B 9071c96e8162d8141676f63aab82ca61ba29039e79066939fb74501187ae95cca34c924f1105827411f021efca2f40a62b7acde845d0d463604b234a3a8f8370 SHA512 df4f2dce732f62c797f77c266e268097f32a5d7605b3464c9a76d323d8ec069c902994df6afa28823d3c03f5d4ca0295cac47e28773b25e2f9387e3475f52f82
 DIST qtbase-5.15.2-7c6c0030.tar.gz 67967537 BLAKE2B 623b99942e9df9bc8ac436a21503060845f9e3532aa0e02ccd927762382be26091878fbe092e80c0ac68bead51d09647e40e0cf61361d62ad226ed46b221132b SHA512 eb88b21764591246c5f04f63405dbfcd39afb737e96bb29c7721644b9aba3ea95df24ed9699acfd03a8c088ee72efec1fb0267aef8d665d5ec72ee75fc08ecdc
 DIST qtbase-5.15.2-f4ac0b55.tar.gz 67967554 BLAKE2B 3e1ece861c195cdaa688f22cac7bbfdb3cce73ac575f72c8adc916face612307553d98da7b757c44980b1ed0ebf5a9ecaa2e993b41e775f511e32bd515c1ca54 SHA512 6160e02505e4d3f9fbd55f442e0a7a4d906feb576c891600232937bc212660b5c8a41072347d9f78dd0a1ca9357af514b5df2b341e181b2c823b36a912e583fa
diff --git a/dev-qt/qtcore/qtcore-5.15.2-r13.ebuild b/dev-qt/qtcore/qtcore-5.15.2-r13.ebuild
deleted file mode 100644
index 0b8f86d5973a..000000000000
--- a/dev-qt/qtcore/qtcore-5.15.2-r13.ebuild
+++ /dev/null
@@ -1,104 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-KDE_ORG_COMMIT=38ad2f39daec09168728033969265834b6a2d924
-QT5_MODULE="qtbase"
-inherit linux-info qt5-build
-
-DESCRIPTION="Cross-platform application development framework"
-SLOT=5/${QT5_PV}
-
-if [[ ${QT5_BUILD_TYPE} == release ]]; then
-	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
-fi
-
-IUSE="icu old-kernel systemd"
-
-DEPEND="
-	dev-libs/double-conversion:=
-	dev-libs/glib:2
-	dev-libs/libpcre2[pcre16,unicode]
-	sys-libs/zlib:=
-	icu? ( dev-libs/icu:= )
-	!icu? ( virtual/libiconv )
-	systemd? ( sys-apps/systemd:= )
-"
-RDEPEND="${DEPEND}
-	>=dev-qt/qtchooser-66-r1
-"
-
-QT5_TARGET_SUBDIRS=(
-	src/tools/bootstrap
-	src/tools/moc
-	src/tools/rcc
-	src/corelib
-	src/tools/qlalr
-	doc
-)
-
-QT5_GENTOO_PRIVATE_CONFIG=(
-	!:network
-	!:sql
-	!:testlib
-	!:xml
-)
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-5.14.1-cmake-macro-backward-compat.patch # bug 703306
-	"${FILESDIR}"/${PN}-5.15.1-timezone-{1,2}.patch # bug 737914
-)
-
-pkg_pretend() {
-	use kernel_linux || return
-	get_running_version
-	if kernel_is -lt 4 11 && ! use old-kernel; then
-		ewarn "The running kernel is older than 4.11. USE=old-kernel is needed for"
-		ewarn "dev-qt/qtcore to function on this kernel properly. Bugs #669994, #672856"
-	fi
-}
-
-src_prepare() {
-	# don't add -O3 to CXXFLAGS, bug 549140
-	sed -i -e '/CONFIG\s*+=/s/optimize_full//' src/corelib/corelib.pro || die
-
-	# fix missing qt_version_tag symbol w/ LTO, bug 674382
-	sed -i -e 's/^gcc:ltcg/gcc/' src/corelib/global/global.pri || die
-
-	qt5-build_src_prepare
-}
-
-src_configure() {
-	local myconf=(
-		$(qt_use icu)
-		$(qt_use !icu iconv)
-		$(qt_use systemd journald)
-	)
-	use old-kernel && myconf+=(
-		-no-feature-renameat2 # needs Linux 3.16, bug 669994
-		-no-feature-getentropy # needs Linux 3.17, bug 669994
-		-no-feature-statx # needs Linux 4.11, bug 672856
-	)
-	qt5-build_src_configure
-}
-
-src_install() {
-	qt5-build_src_install
-
-	local flags=(
-		DBUS FREETYPE IMAGEFORMAT_JPEG IMAGEFORMAT_PNG
-		OPENGL OPENSSL SSL WIDGETS
-	)
-
-	for flag in ${flags[@]}; do
-		cat >> "${D}"/${QT5_HEADERDIR}/QtCore/qconfig.h <<- _EOF_ || die
-
-			#if defined(QT_NO_${flag}) && defined(QT_${flag})
-			# undef QT_NO_${flag}
-			#elif !defined(QT_NO_${flag}) && !defined(QT_${flag})
-			# define QT_NO_${flag}
-			#endif
-		_EOF_
-	done
-}