app-crypt/{kbfs,keybase}: Version bump to 6.2.4

Closes: https://bugs.gentoo.org/921016
Closes: https://github.com/gentoo/gentoo/pull/34712
Signed-off-by: Nicolas Bock <nicolasbock@gentoo.org>

6 files changed, 147 insertions, 4 deletions

diff --git a/app-crypt/kbfs/Manifest b/app-crypt/kbfs/Manifest
index 084c14bbd06a..5cef4e7b17bf 100644
--- a/app-crypt/kbfs/Manifest
+++ b/app-crypt/kbfs/Manifest
@@ -1,2 +1,4 @@
 DIST kbfs-6.0.2-deps.tar.xz 205729260 BLAKE2B d58d1b6615c9195ad3b4eb82bbbb3f3ff4729683b6d4b69dd35222089fa9477710a59c75af830a4f74ca6ccf3eae2fe6d880a72b74d15478fe29db268f333f64 SHA512 39afab3647ea766ed86059548eddc910195ec39b71897a92cdc927d9c0025297254950c0a85434ce9a1e90a189b6f84504445e1d6152ec4bd8441dd55ae4e6c0
 DIST kbfs-6.0.2.tar.gz 57283593 BLAKE2B 272dd3c9e2e855e1979a620f5a600cb1352632fca055ba36140d2cc63013e8f8b7e66c5f9fe74ab2c71dac2df7cc27aac9a8387f7444eff4c469659ff1aece2e SHA512 0a3fe3f8b9fc7a3099696699268bec54aed898d0692a3033e54f816b87ef2616b83a0817d365b87a77ecb489ae5d11bae15597c3bcd23819422ec384ae63f6a0
+DIST kbfs-6.2.4-deps.tar.xz 118668392 BLAKE2B e03bf3698021c3f1c841cee5d815ec57f9ec1bdbe6f4afc12e6facc56085874153f4f80342b6ff00ad74fc75bce3a7a1d0795abd4d22d040cfea38b288368f2c SHA512 b67928419619a6caaa2dc2e15211412292a3c33ec910a97c444b66adb6318f0a7c7efa7e23473cc2bc0c91b7c49e37977016639394d0754fb2c9e15e1905c421
+DIST kbfs-6.2.4.tar.gz 53209004 BLAKE2B 5d44b8d0764b5d41635ec431afb8b0b8ed0693b574ead82134f187e97efce5ab206f3c18f570033acdf144589a36ff6e328d55ee32c0a7707aeb110b415bc771 SHA512 fd6b78e63b7df6838f7ad80f36adc93171e48794e6903f561d9f3489f61dba8db7757a1dd1d65cfa35970716f406de963e126c20ba93cfdaf48d2ddd41d0925e
diff --git a/app-crypt/kbfs/kbfs-6.2.4.ebuild b/app-crypt/kbfs/kbfs-6.2.4.ebuild
new file mode 100644
index 000000000000..835f820a30b0
--- /dev/null
+++ b/app-crypt/kbfs/kbfs-6.2.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module systemd
+
+DESCRIPTION="Keybase Filesystem (KBFS)"
+HOMEPAGE="https://keybase.io/docs/kbfs"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/keybase/client.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/keybase/client/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI+=" https://dev.gentoo.org/~nicolasbock/${P}-deps.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+RDEPEND="
+	app-crypt/gnupg
+	sys-fs/fuse:0=
+"
+
+src_unpack() {
+	default
+	if [[ ${PV} == *9999 ]]; then
+		git-r3_src_unpack
+		GOMODCACHE="${S}/go/go-mod"
+		pushd "${S}/go" || die
+		ego mod download
+		popd || die
+	else
+		ln -vs "client-${PV}" "${P}" || die
+		mkdir -vp "${S}/src/github.com/keybase" || die
+		ln -vs "${S}" "${S}/src/github.com/keybase/client" || die
+	fi
+}
+
+src_compile() {
+	pushd ./go/kbfs/kbfsfuse || die
+	ego build -tags production -o "${T}/kbfsfuse"
+	popd || die
+	pushd ./go/kbfs/kbfsgit/git-remote-keybase || die
+	ego build -tags production -o "${T}/git-remote-keybase"
+	popd || die
+	pushd ./go/kbfs/redirector || die
+	ego build -tags production -o "${T}/keybase-redirector"
+	popd || die
+}
+
+src_test() {
+	pushd ./go/kbfs/kbfsfuse || die
+	ego test
+	popd || die
+}
+
+src_install() {
+	dobin "${T}/kbfsfuse"
+	dobin "${T}/git-remote-keybase"
+	dobin "${T}/keybase-redirector"
+	systemd_douserunit "${S}/packaging/linux/systemd/kbfs.service"
+	systemd_douserunit "${S}/packaging/linux/systemd/keybase-redirector.service"
+}
diff --git a/app-crypt/kbfs/kbfs-9999.ebuild b/app-crypt/kbfs/kbfs-9999.ebuild
index b43cf2f164e1..835f820a30b0 100644
--- a/app-crypt/kbfs/kbfs-9999.ebuild
+++ b/app-crypt/kbfs/kbfs-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -12,7 +12,7 @@ if [[ ${PV} == *9999 ]]; then
 	EGIT_REPO_URI="https://github.com/keybase/client.git"
 	inherit git-r3
 else
-	SRC_URI="https://github.com/keybase/client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/keybase/client/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
 	SRC_URI+=" https://dev.gentoo.org/~nicolasbock/${P}-deps.tar.xz"
 	KEYWORDS="~amd64 ~arm64 ~x86"
 fi
diff --git a/app-crypt/keybase/Manifest b/app-crypt/keybase/Manifest
index 55dcb4b87bc2..27a0fd8b9172 100644
--- a/app-crypt/keybase/Manifest
+++ b/app-crypt/keybase/Manifest
@@ -1,2 +1,4 @@
 DIST keybase-6.0.2-deps.tar.xz 202450984 BLAKE2B da3ec411dc06203da08bd472c9842258ad58de9caac9948a84c4a840f1503bb5959a2ce9ddfdec966c6c20a0729fb562666898d21c799fc8c263d6a8924c2fef SHA512 8c22eb2036987ccd131c0b68e126cecf8bf795d4e8366e1f9d2f07d947556094977e1066449dc82fb955f3f8773217822574d70675212d568fc0900f9127b6e6
 DIST keybase-6.0.2.tar.gz 57283593 BLAKE2B 272dd3c9e2e855e1979a620f5a600cb1352632fca055ba36140d2cc63013e8f8b7e66c5f9fe74ab2c71dac2df7cc27aac9a8387f7444eff4c469659ff1aece2e SHA512 0a3fe3f8b9fc7a3099696699268bec54aed898d0692a3033e54f816b87ef2616b83a0817d365b87a77ecb489ae5d11bae15597c3bcd23819422ec384ae63f6a0
+DIST keybase-6.2.4-deps.tar.xz 253783064 BLAKE2B f97c4031a7379da1060031f8e20667213bb54647f192aedf3f510b0a87d769f4ef11df8cd23b56c96bc09b24b78d0e82adde9559919149d3a041bb53d59eaf9c SHA512 a0810219901a50b3b06879581141e3a3b337c8853eeb02551f65ce1029b7cc6e57d154a7a201490fa651771ef0fe0dc5b2c71956a66ffee753c96f1420cb93b3
+DIST keybase-6.2.4.tar.gz 53209004 BLAKE2B 5d44b8d0764b5d41635ec431afb8b0b8ed0693b574ead82134f187e97efce5ab206f3c18f570033acdf144589a36ff6e328d55ee32c0a7707aeb110b415bc771 SHA512 fd6b78e63b7df6838f7ad80f36adc93171e48794e6903f561d9f3489f61dba8db7757a1dd1d65cfa35970716f406de963e126c20ba93cfdaf48d2ddd41d0925e
diff --git a/app-crypt/keybase/keybase-6.2.4.ebuild b/app-crypt/keybase/keybase-6.2.4.ebuild
new file mode 100644
index 000000000000..e7a1f0027806
--- /dev/null
+++ b/app-crypt/keybase/keybase-6.2.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module systemd
+
+DESCRIPTION="Keybase client"
+HOMEPAGE="https://keybase.io/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/keybase/client.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/keybase/client/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI+=" https://dev.gentoo.org/~nicolasbock/${P}-deps.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="Apache-2.0 BSD BSD-2 LGPL-3 MIT MPL-2.0"
+SLOT="0"
+IUSE="fuse"
+
+RDEPEND="
+	app-crypt/gnupg
+	fuse? (
+		~app-crypt/kbfs-${PV}
+	)
+"
+
+src_unpack() {
+	default
+	if [[ ${PV} == *9999 ]]; then
+		git-r3_src_unpack
+		GOMODCACHE="${S}/go/go-mod"
+		pushd "${S}/go" || die
+		ego mod download
+		popd || die
+	else
+		ln -vs "client-${PV}" "${P}" || die
+		mkdir -vp "${S}/src/github.com/keybase" || die
+		ln -vs "${S}" "${S}/src/github.com/keybase/client" || die
+	fi
+}
+
+src_compile() {
+	pushd go/keybase || die
+	ego build -tags production -o "${T}/keybase"
+	popd || die
+}
+
+src_test() {
+	pushd go/keybase || die
+	ego test
+	popd || die
+}
+
+src_install() {
+	dobin "${T}/keybase"
+	dobin "${S}/packaging/linux/run_keybase"
+	systemd_douserunit "${S}/packaging/linux/systemd/keybase.service"
+	insinto "/opt/keybase"
+	doins "${S}/packaging/linux/crypto_squirrel.txt"
+	dodir "/opt/keybase"
+}
+
+pkg_postinst() {
+	elog "Start/Restart keybase: run_keybase"
+	elog "Run the service:       keybase service"
+	elog "Run the client:        keybase login"
+	ewarn "Note that the user keybasehelper is obsolete and can be removed"
+}
diff --git a/app-crypt/keybase/keybase-9999.ebuild b/app-crypt/keybase/keybase-9999.ebuild
index cce66b1ede2e..e7a1f0027806 100644
--- a/app-crypt/keybase/keybase-9999.ebuild
+++ b/app-crypt/keybase/keybase-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -12,7 +12,7 @@ if [[ ${PV} == *9999 ]]; then
 	EGIT_REPO_URI="https://github.com/keybase/client.git"
 	inherit git-r3
 else
-	SRC_URI="https://github.com/keybase/client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/keybase/client/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
 	SRC_URI+=" https://dev.gentoo.org/~nicolasbock/${P}-deps.tar.xz"
 	KEYWORDS="~amd64 ~arm64 ~x86"
 fi