dev-python/sympy: add 1.11

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 67 insertions, 0 deletions

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index 3de66a97f00f..fa1689ebec86 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1 +1,2 @@
 DIST sympy-1.10.1.tar.gz 7666681 BLAKE2B e522e71058ebc8bdf3c016e3067bae9138e9a9a15ea658cba1fd35a04ce58246b5c3d7ab9c231d7071ed20b588ecfaa9275f383825b511a40c9821eadb53dd44 SHA512 7b6d5718826951bb1e477a78c3de8b95b8edda103981ad03c9f0da125ad35d72d8e5b5716d478ac4f00810939f1dc35786cc2e0a6b75cffb098cc1be9d8f7168
+DIST sympy-1.11.tar.gz 13462278 BLAKE2B 8129ac3b3a02930f05d3e9b8bbf3d224be9a92743a4ae5c518d34bd8bb2bffee1ceb3bac8b24423752d82cfdebaed7f72b51a8383a48080b7c3f8c7ce1e49c3d SHA512 4ecebe3ed363c0ccc365df0b7ffbafdde7d8a3012feda4e9c4b54b77f4b73b46cac949070d0e7ddd2ec350c18eb54a11f6abd6cd40e476eed0f1ded18c99fc09
diff --git a/dev-python/sympy/sympy-1.11.ebuild b/dev-python/sympy/sympy-1.11.ebuild
new file mode 100644
index 000000000000..b75ed090fb89
--- /dev/null
+++ b/dev-python/sympy/sympy-1.11.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="https://www.sympy.org/"
+SRC_URI="https://github.com/sympy/sympy/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="aesara examples imaging ipython latex mathml opengl pdf png pyglet symengine test texmacs"
+
+RDEPEND="
+	dev-python/mpmath[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	aesara? ( dev-python/aesara[${PYTHON_USEDEP}] )
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? ( dev-python/ipython[${PYTHON_USEDEP}] )
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-libs/libxml2:2[${PYTHON_USEDEP}] )
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}