app-text/ansifilter: version bump 2.17

Closes: https://bugs.gentoo.org/713524
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/app-text/ansifilter/Manifest b/app-text/ansifilter/Manifest
index 6047e7eeea8a..5d225342d09b 100644
--- a/app-text/ansifilter/Manifest
+++ b/app-text/ansifilter/Manifest
@@ -1 +1,2 @@
 DIST ansifilter-2.16.tar.bz2 441932 BLAKE2B 7a6af4e4b78cd4c26551791b4661a6f41c397a65abe19667f049bd393af0c5e1453a3f7f5f56c7d321c41c2cf36acc05575bb866f5dbf04184de1069d6c64a20 SHA512 ef621087e6d522e08423802d223f826f2fd6fe3b2efd8ed26e09f64e666202cdcdf68d19ebe5ac4b858a4339a8aa4d5f2ba309efa310837808381e09e39d4f90
+DIST ansifilter-2.17.tar.bz2 436116 BLAKE2B 94a1788cffa66343643f48a18748d5359b090803cde723a02bc38f908c262631f1cd2eb150b6a743d66caa04983ea444ba150cf34ce07bdb456979e19631582f SHA512 ab9d590189482f2a27affd62b456c96b947b04d8c8b1214f1ea967971c8ed7df8a7c15d1079f957164d01916d144dcd5dc4b0ac05b452f9f4b8095273d3d3162
diff --git a/app-text/ansifilter/ansifilter-2.17.ebuild b/app-text/ansifilter/ansifilter-2.17.ebuild
new file mode 100644
index 000000000000..105e431f1147
--- /dev/null
+++ b/app-text/ansifilter/ansifilter-2.17.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs qmake-utils
+
+DESCRIPTION="Handles text files containing ANSI terminal escape codes"
+HOMEPAGE="http://www.andre-simon.de/"
+SRC_URI="http://www.andre-simon.de/zip/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="qt5"
+
+RDEPEND="
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}"
+
+DOCS=( ChangeLog.adoc README.adoc  )
+
+src_prepare() {
+	default
+
+	# bug 431452
+	rm src/qt-gui/moc_mydialog.cpp || die
+
+	sed -e "s/-O2//" -i src/makefile || die
+}
+
+src_configure() {
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		eqmake5
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	emake -f makefile CXX="$(tc-getCXX)"
+
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		emake
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	dobin src/${PN}
+	if use qt5 ; then
+		dobin src/qt-gui/${PN}-gui
+		insinto /usr/share/applications
+		doins ${PN}.desktop
+	fi
+
+	doman man/${PN}.1
+	einstalldocs
+}