dev-python/pytest: 4.3.0 version bump

Closes: https://bugs.gentoo.org/678458
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/11123
Signed-off-by: Virgil Dupras <vdupras@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index f31640d8403f..1c92fd621005 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -2,3 +2,4 @@ DIST pytest-3.10.1.tar.gz 892420 BLAKE2B 38849ae69bf4380bc1a99aa105cac04be078da4
 DIST pytest-3.2.2.tar.gz 786396 BLAKE2B e669da930890e902b0323ec3a6685080ddd889e74655f7b4cb08ec421651f987597021a31471aab5a32d637b99620ce7792cbdf8f85561db3bb10ff06a446ba1 SHA512 6df3a50e7d1efeaf7a283920b16d1daf800798f422bc851b0aacd2bbd5cb0a88c95f9057fae49943b9dfe6527ed552cdf8d983b944ab91d0af252ee4f6eb82db
 DIST pytest-3.4.2.tar.gz 812719 BLAKE2B 96623d6cdea4bd79778175c18c949938505f1862010f700f9a8cb85f445910381af391a5b69e664fbbfc254bf46502c798c72026772070236a0a3bca7aeeb3d6 SHA512 787065ab76d4482799bb2da9f024c9c383e68cc1cc01f3b80f6ed9444ca6383d20953615696ed4dd01668777b094cf5002b23c4ce51828879dcf8ebf2170c71b
 DIST pytest-4.2.1.tar.gz 913065 BLAKE2B cde085627872d601df1c6d91d9620fbb97789b6e176fe104bc991faa800268e5e61651e211a8840743b21f8cd9b57dcee8685143e2f4d56d197afae35a577aed SHA512 e41bf7c685cacd62261df6d356911297a65ba85e13a50f8aed23d382d257c4c1cd3213971a3970fec210b8e97b72bd0034c0c1f87be7f306286d541c5ea57097
+DIST pytest-4.3.0.tar.gz 915820 BLAKE2B ee8c55bb3a6e79d4897b218f372f8b0ceb524ea627f2e803484d83791ebe979da760695d3f6d7d85bc6494bdee1079f71aaf2418f1bd9e2318aba7471445413e SHA512 67894dc6c7001290e3372b5015227cf800c02d40ff28f76fad1249bd866f25c2368d8f0895d7c97a6b3318608f88e44db0bff723e7aeef79e380227cd7ec147e
diff --git a/dev-python/pytest/pytest-4.3.0.ebuild b/dev-python/pytest/pytest-4.3.0.ebuild
new file mode 100644
index 000000000000..ab4d81909734
--- /dev/null
+++ b/dev-python/pytest/pytest-4.3.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple powerful testing with Python"
+HOMEPAGE="http://pytest.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+# When bumping, please check setup.py for the proper py version
+PY_VER="1.5.0"
+
+# pathlib2 has been added to stdlib before py3.6, but pytest needs __fspath__
+# support, which only came in py3.6.
+RDEPEND="
+	>=dev-python/atomicwrites-1.0[${PYTHON_USEDEP}]
+	>=dev-python/attrs-17.4.0[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-4.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/pathlib2[${PYTHON_USEDEP}]' python2_7 python3_{4,5} )
+	>=dev-python/pluggy-0.7[${PYTHON_USEDEP}]
+	>=dev-python/py-${PY_VER}[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-40[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	virtual/python-funcsigs[${PYTHON_USEDEP}]"
+
+# flake & pytest-capturelog cause a number of tests to fail
+DEPEND="${RDEPEND}
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2)
+		dev-python/requests[${PYTHON_USEDEP}]
+		!!dev-python/flaky
+		!!dev-python/pytest-capturelog
+		!!<dev-python/pytest-xdist-1.22
+	)"
+
+python_prepare_all() {
+	grep -qF "py>=${PY_VER}" setup.py || die "Incorrect dev-python/py dependency"
+
+	# Something in the ebuild environment causes this to hang/error.
+	# https://bugs.gentoo.org/598442
+	rm testing/test_pdb.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# In v4.1.1, pytest started being picky about its own verbosity options.
+	# running pytest on itself with -vv made 3 tests fail. This is why we don't
+	# have it below.
+	"${EPYTHON}" "${BUILD_DIR}"/lib/pytest.py --lsof -rfsxX \
+		|| die "tests failed with ${EPYTHON}"
+}