sys-apps/gnome-disk-utility: bump to 3.34.5

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/sys-apps/gnome-disk-utility/Manifest b/sys-apps/gnome-disk-utility/Manifest
index 573f4291d721..678a7760a48f 100644
--- a/sys-apps/gnome-disk-utility/Manifest
+++ b/sys-apps/gnome-disk-utility/Manifest
@@ -1 +1,2 @@
 DIST gnome-disk-utility-3.32.1.tar.xz 1370900 BLAKE2B 4986169bff7f438b4a9dc9fe10ea69521c41afaa268bfebdf195ff3fedc14e0d8204e66b258c71f599867c0279c781ca5ceb175381dcc8004c41d97be92ebf46 SHA512 80c4e2fb1ca6136579203c3df73da4c8ef7d496ab73166096768d72b3473d11e9ae199d4aa1878c49ec4280ea98d2136e084a03bba50c2728be4c5e4d508967c
+DIST gnome-disk-utility-3.34.5.tar.xz 1385256 BLAKE2B d13202abf77c62cdbf483486d7ed8204016111042f29fc810f0a55a9cd3dd48553d523523348e73a5d3dc3c3133939577b14227f2f5122471076cd93482dde15 SHA512 04c1ba0865b3947cfc332e479faae7b404f70907d04446bfe471d8fa2f8f5c921b1d59ab0f82fad13f4183401dacf3a516ee7ec439e94dc3e073a8dd62021a51
diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-3.34.5.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-3.34.5.ebuild
new file mode 100644
index 000000000000..a46e8ca17e2b
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-3.34.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat elogind gnome systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+
+DEPEND="
+	>=media-libs/libdvdread-4.2.0:0=
+	>=dev-libs/glib-2.31:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=app-arch/xz-utils-5.0.5
+	>=x11-libs/libnotify-0.7:=
+	>=app-crypt/libsecret-0.7
+	>=dev-libs/libpwquality-1.0.0
+	>=sys-fs/udisks-2.7.6:2
+	elogind? ( >=sys-auth/elogind-209 )
+	systemd? ( >=sys-apps/systemd-209:0= )
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+# libxml2 for xml-stripblanks in gresource
+BDEPEND="
+	dev-libs/libxml2:2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dlogind=$(usex systemd libsystemd $(usex elogind libelogind none))
+		$(meson_use gnome gsd_plugin)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}