app-admin/system-config-printer: 1.5.15 version bump

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 77 insertions, 0 deletions

diff --git a/app-admin/system-config-printer/Manifest b/app-admin/system-config-printer/Manifest
index 8b8fc1e07b46..c53bcf490fa9 100644
--- a/app-admin/system-config-printer/Manifest
+++ b/app-admin/system-config-printer/Manifest
@@ -1,2 +1,3 @@
 DIST system-config-printer-1.5.13.tar.xz 974532 BLAKE2B 44e748d2fc20edefe58e1c8dd3781aff28af93e57356a9969e051813bf4f04f72c4e895b587e86614df6fb4984a4d610e8e1a1e17777801ae8912b6904679c72 SHA512 f4fbc1b20b35aa5b33bafdffc8a7490cc3c55e0b33bd9e925f1d3e01532c0a7bb87f80a04dd6da6fc492edd9fea74bacb0ce16ff64ceac622722fe1f9a77a6b7
 DIST system-config-printer-1.5.14.tar.xz 1005400 BLAKE2B 23f96a079e568afc098cc505d32b02d1fe14e8e43bf24032c890d8c924f754def194525a8188719873c3c4b693666c1ef83f19b8bbe89846fc2c32ed48abe4da SHA512 5aa0f9f7d3a6e15acc1c2fdc62cc6c10bc686a62fbfd2b97aa61e1d6d1d690019fc461b6db54d6340668f52d52764cc0b2cd59b02b5061b7f44577f2c2b19fe9
+DIST system-config-printer-1.5.15.tar.xz 1005764 BLAKE2B 4919c555444829505b09b658ce0fd016ba235260f8c8b4db751e6a511afba5d5975e5f9570f5fe74fc35d158bbf2dd3ece99aa568ec1bb850096e5f12f0fc0b0 SHA512 b992f96f48c54350c11c5c629e77ee4409fe52fb17b386f226a42d532a95e17b6506319dcedeb70c0072555cb9ab464daaae22f295ce3d5181e5f49836f2ae2e
diff --git a/app-admin/system-config-printer/system-config-printer-1.5.15.ebuild b/app-admin/system-config-printer/system-config-printer-1.5.15.ebuild
new file mode 100644
index 000000000000..2ea09c424a65
--- /dev/null
+++ b/app-admin/system-config-printer/system-config-printer-1.5.15.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="xml"
+inherit python-single-r1 systemd xdg
+
+DESCRIPTION="Graphical user interface for CUPS administration"
+HOMEPAGE="https://github.com/OpenPrinting/system-config-printer"
+SRC_URI="https://github.com/OpenPrinting/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gnome-keyring policykit"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Needs cups running, bug 284005
+RESTRICT="test"
+
+# Additional unhandled dependencies
+# gnome-extra/gnome-packagekit[${PYTHON_USEDEP}] with pygobject:2 ?
+# python samba client: smbc
+# selinux: needed for troubleshooting
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/glib:2
+	net-print/cups[dbus]
+	virtual/libusb:1
+	>=virtual/udev-172
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	>=app-text/xmlto-0.0.22
+	dev-perl/XML-Parser
+	dev-util/desktop-file-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycups[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		dev-python/requests[${PYTHON_MULTI_USEDEP}]
+		dev-python/urllib3[${PYTHON_MULTI_USEDEP}]
+	')
+	gnome-keyring? ( app-crypt/libsecret[introspection] )
+	policykit? ( net-print/cups-pk-helper )
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-nls
+		--with-desktop-vendor=Gentoo
+		--with-udev-rules
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	python_fix_shebang "${ED}"
+	python_optimize
+}