sys-apps/attr: add 2.5.2

Thanks vapier!

Bug: https://bugs.gentoo.org/644048
Bug: https://bugs.gentoo.org/700116
Closes: https://bugs.gentoo.org/644058
Closes: https://bugs.gentoo.org/790581
Closes: https://bugs.gentoo.org/912735
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 78 insertions, 28 deletions

diff --git a/sys-apps/attr/Manifest b/sys-apps/attr/Manifest
index e7ed8d74a0fe..0e025eaf233d 100644
--- a/sys-apps/attr/Manifest
+++ b/sys-apps/attr/Manifest
@@ -1 +1,2 @@
 DIST attr-2.5.1.tar.xz 318188 BLAKE2B 876dcbd802ea79b7851640f208820ffdfb73dc46065af673037c6dd50ad2af158f9f74b34cf45728baf9d0cc5572b40c3f102aa2907245a877db0d3879e38f04 SHA512 9e5555260189bb6ef2440c76700ebb813ff70582eb63d446823874977307d13dfa3a347dfae619f8866943dfa4b24ccf67dadd7e3ea2637239fdb219be5d2932
+DIST attr-2.5.2.tar.xz 334180 BLAKE2B cf26348c3a96622e4f62493ac7655e14b6580d36a5784ef4c3750178856eceabd33192fd58516be21c8aa1ad41d56c024ad440ef4bc922bed8f7a4984ea16c63 SHA512 f587ea544effb7cfed63b3027bf14baba2c2dbe3a9b6c0c45fc559f7e8cb477b3e9a4a826eae30f929409468c50d11f3e7dc6d2500f41e1af8662a7e96a30ef3
diff --git a/sys-apps/attr/attr-2.5.2.ebuild b/sys-apps/attr/attr-2.5.2.ebuild
new file mode 100644
index 000000000000..0c5a2dce3464
--- /dev/null
+++ b/sys-apps/attr/attr-2.5.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal usr-ldscript
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/${PN}.git"
+	inherit autotools git-r3
+else
+	inherit libtool
+
+	SRC_URI="mirror://nongnu/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="Extended attributes tools"
+HOMEPAGE="https://savannah.nongnu.org/projects/attr"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="debug nls static-libs"
+
+BDEPEND="nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999 ]] ; then
+		po/update-potfiles || die
+		eautopoint
+		eautoreconf
+	else
+		# bug #580792
+		elibtoolize
+	fi
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/bin
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable nls)
+		$(use_enable debug)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi; then
+		# We install attr into /bin, so we need the shared lib with it
+		gen_usr_ldscript -a attr
+	fi
+
+	# Add a wrapper until people upgrade.
+	# TODO: figure out when this was added & when we can drop it!
+	insinto /usr/include/attr
+	newins "${FILESDIR}"/xattr-shim.h xattr.h
+}
+
+multilib_src_install_all() {
+	if ! use static-libs; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+
+	einstalldocs
+}
diff --git a/sys-apps/attr/attr-9999.ebuild b/sys-apps/attr/attr-9999.ebuild
index f5ee0bed082e..0c5a2dce3464 100644
--- a/sys-apps/attr/attr-9999.ebuild
+++ b/sys-apps/attr/attr-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-inherit toolchain-funcs multilib-minimal usr-ldscript
+inherit multilib-minimal usr-ldscript
 
 if [[ ${PV} == 9999 ]] ; then
 	EGIT_REPO_URI="https://git.savannah.gnu.org/git/${PN}.git"
@@ -11,23 +11,19 @@ if [[ ${PV} == 9999 ]] ; then
 else
 	inherit libtool
 
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
 	SRC_URI="mirror://nongnu/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
 fi
 
 DESCRIPTION="Extended attributes tools"
 HOMEPAGE="https://savannah.nongnu.org/projects/attr"
 
-LICENSE="LGPL-2.1"
+LICENSE="LGPL-2.1+"
 SLOT="0"
 IUSE="debug nls static-libs"
 
 BDEPEND="nls? ( sys-devel/gettext )"
 
-PATCHES=(
-	"${FILESDIR}"/${PN}-2.5.1-r2-fix-symver.patch
-)
-
 src_prepare() {
 	default
 
@@ -57,26 +53,6 @@ multilib_src_configure() {
 multilib_src_install() {
 	emake DESTDIR="${D}" install
 
-	# Sanity check until we track down why this is happening. bug #644048
-	local lib="${ED}/usr/$(get_libdir)/libattr.so.1"
-	if [[ -e ${lib} ]] ; then
-		local versions=$($(tc-getREADELF) -V "${lib}")
-		local symbols=$($(tc-getREADELF) -sW "${lib}")
-		if [[ "${versions}" != *"ATTR_1.0"* || \
-		      "${versions}" != *"ATTR_1.1"* || \
-		      "${versions}" != *"ATTR_1.2"* || \
-		      "${versions}" != *"ATTR_1.3"* || \
-		      "${symbols}" != *"getxattr@ATTR_1.0"* ]] ; then
-			echo "# readelf -V ${lib}"
-			echo "${versions}"
-			echo "# readelf -sW ${lib}"
-			echo "${symbols}"
-			die "Symbol version sanity check failed; please comment on https://bugs.gentoo.org/644048"
-		else
-			einfo "${lib} passed symbol checks"
-		fi
-	fi
-
 	if multilib_is_native_abi; then
 		# We install attr into /bin, so we need the shared lib with it
 		gen_usr_ldscript -a attr