app-backup/dar: Bump to versions 2.4.23 and 2.5.7

Package-Manager: portage-2.3.2
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

3 files changed, 167 insertions, 0 deletions

diff --git a/app-backup/dar/Manifest b/app-backup/dar/Manifest
index 04a26c505f0a..9cf2201c07d8 100644
--- a/app-backup/dar/Manifest
+++ b/app-backup/dar/Manifest
@@ -1,5 +1,7 @@
 DIST dar-2.4.20.tar.gz 1804634 SHA256 f0f66108692de8b27e76b1832d9013d9d1dbf45d2aaaaf5c222dde3c6f1b308d SHA512 1ed2e43df05082c01f6a53aa8c1c7328cb27fc3d84115d3f4a07de943fc814b614155f673464cd1a455e3b8c21e30f95da03ed9f72883b58ae005e3696de8143 WHIRLPOOL b3ce8c59efe2f9f988133613b73fe1ec14af39746e7c5fff0c83fa2146218fad3e912f586e9b677af809696105fa9d72dc35122ec3b3ca3ad63b2cdd75fce954
 DIST dar-2.4.22.tar.gz 1802561 SHA256 19a977e3ca7ed15e4406bb3e08ff2b8225d291a5c4189a6d5b7b3d75eea50f2b SHA512 1eb809e6388be7e0c11961b1cd84712e5a94ff5fcbfd4fb66ed5a9aa23e01e7b99ba7300491ea383517b99af289c2d2bb9eab904c0511f23610bbb8feee4575c WHIRLPOOL 6156344a471ae23afae6b58e9bbb030a1d829425c086561843a388873cb5003ea09ec1fdd11245bad2e12a40cc10155e490bef1ef68de5ad9915a5f51f98f93a
+DIST dar-2.4.23.tar.gz 1819248 SHA256 2338b5bdd17168db10aed75a2cf6abb99e8058a4e67eba3bfaaec457c04725b1 SHA512 c9c737f9310eb84aaf0743139b9bacc07dab853a6cc0572882f54a80b6e15aac41af6151b6ca38db61b131fdb05d5cd0e9e6269cdf5bdd3698ce0df754a152c8 WHIRLPOOL 35a6e80d7f0dfa8dd7f5385c33ee0ee375f284223a0f268c1eb3a77f8ef2f222a7ae8a5e2d78e60ff5b2d59d9aa106f0b14449e61d3166564a8ca23cfbf3e5e4
 DIST dar-2.4.9.tar.gz 1751738 SHA256 3d11159a290886dde968e16d36f32fa8640029708457bc87cc0da6d0eac71643 SHA512 9a9b972599747493694fd838bafaa690e70490b5c500f084f0d0225e93a54ce40d61bc495827519c88f6a94542b88a1be5d11e5a98e672abe8659364d1b4c51f WHIRLPOOL f700bf7bd393e6dc2cce11e7bc56af0f130ea3fb714de04617a940ec15d6174c06b7a1051eb9c6ffa7a0ec686b1f13c288af1b541d49b332932743d0d617b56b
 DIST dar-2.5.5.tar.gz 1861378 SHA256 aa77d6778206b00ad7b37d5f615aafff3ea770b35d96625429c14ff67b78466d SHA512 202f1b35a4b74d60215768deffe24b745bba699b880dd4228dff3a983cbfdcd6e5f739cf81073d937d793f188f44339cfeb712e2874533b01cce49b0a451c306 WHIRLPOOL fccac49a2f52adafb226c77f3ba0418fbcbe913fb80646e873a206f5d44cd693bd2be5f4dc1839957019ee500d70cd5a272e86a21ce1774d6d17ceeb3d7cd5e0
 DIST dar-2.5.6.tar.gz 1879556 SHA256 47db04275d9f10f3a074e226d6fe760184e9694f1811a98f0b41e4f1dee30815 SHA512 cb707e7f95917de6eb0d221effe380d75abf49cd28bd97dd4a9056032f465aba5ee02eca08554fd5154bc4664946564723a6defa7d5d9cc4d9e62fe690e2095e WHIRLPOOL e9930b21b2d319b3df6e5f0bd1b19e4900b5863232a682b62c4324f13eafdb74e530ca8dc3b92801758f7facb1d20a21706cbbaa4436ac5a2a8ff163d582660c
+DIST dar-2.5.7.tar.gz 1881075 SHA256 f4fa3b5d8d38a299e4463dbf77e104c572be669838e16a3d507dce7173d1561d SHA512 b8b81e31c63713fbacb79a1da17c5b2be4506e44b64667fe32ffbd5e5720798c7d34b000a6c78cb3ae482c77da00bd0f4169827c030b441a93861171dc73e98a WHIRLPOOL 5ef24ef7c4913474e5c6746e821f6d979fee118e1757a228742b444155998a280fccb32d108c777d1cf01904a9b38a07850e9d35bff43626217accee611f2f31
diff --git a/app-backup/dar/dar-2.4.23.ebuild b/app-backup/dar/dar-2.4.23.ebuild
new file mode 100644
index 000000000000..fdb00454f28e
--- /dev/null
+++ b/app-backup/dar/dar-2.4.23.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="acl dar32 dar64 doc gcrypt lzo nls static static-libs"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND=">=sys-libs/zlib-1.2.3:=
+	!static? ( app-arch/bzip2:= )
+	acl? ( !static? ( sys-apps/attr:= ) )
+	gcrypt? ( dev-libs/libgcrypt:0= )
+	lzo? ( !static? ( dev-libs/lzo:= ) )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	static? ( app-arch/bzip2[static-libs] )
+	static? ( sys-libs/zlib[static-libs] )
+	acl? ( static? ( sys-apps/attr[static-libs] ) )
+	lzo? ( static? ( dev-libs/lzo[static-libs] ) )
+	nls? ( sys-devel/gettext )
+	doc? ( app-doc/doxygen )"
+
+REQUIRED_USE="?? ( dar32 dar64 )"
+
+DOCS="AUTHORS ChangeLog NEWS README THANKS TODO"
+
+src_configure() {
+	local myconf="--disable-upx"
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	use acl || myconf="${myconf} --disable-ea-support"
+	use dar32 && myconf="${myconf} --enable-mode=32"
+	use dar64 && myconf="${myconf} --enable-mode=64"
+	use doc || myconf="${myconf} --disable-build-html"
+	# use examples && myconf="${myconf} --enable-examples"
+	use gcrypt || myconf="${myconf} --disable-libgcrypt-linking"
+	use lzo || myconf="${myconf} --disable-liblzo2-linking"
+	use nls || myconf="${myconf} --disable-nls"
+	if ! use static ; then
+		myconf="${myconf} --disable-dar-static"
+		if ! use static-libs ; then
+			myconf="${myconf} --disable-static"
+		fi
+	fi
+
+	econf ${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	einstalldocs
+
+	if ! use static-libs ; then
+		prune_libtool_files --all
+	fi
+}
diff --git a/app-backup/dar/dar-2.5.7.ebuild b/app-backup/dar/dar-2.5.7.ebuild
new file mode 100644
index 000000000000..6986739f195d
--- /dev/null
+++ b/app-backup/dar/dar-2.5.7.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit confutils flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="dar32 dar64 doc gcrypt gpg lzo nls static static-libs xattr"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND=">=sys-libs/zlib-1.2.3:=
+	!static? (
+		app-arch/bzip2:=
+		app-arch/xz-utils:=
+		sys-libs/libcap
+		gcrypt? ( dev-libs/libgcrypt:0= )
+		gpg? ( app-crypt/gpgme )
+		xattr? ( sys-apps/attr:= )
+	)
+	lzo? ( !static? ( dev-libs/lzo:= ) )
+	nls? ( virtual/libintl )"
+
+DEPEND="${RDEPEND}
+	static? (
+		app-arch/bzip2[static-libs]
+		app-arch/xz-utils[static-libs]
+		sys-libs/libcap[static-libs]
+		sys-libs/zlib[static-libs]
+		gcrypt? ( dev-libs/libgcrypt:0=[static-libs] )
+		gpg? (
+			app-crypt/gpgme[static-libs]
+			dev-libs/libassuan[static-libs]
+			dev-libs/libgpg-error[static-libs]
+		)
+		lzo? ( dev-libs/lzo[static-libs] )
+		xattr? ( sys-apps/attr[static-libs] )
+	)
+	nls? ( sys-devel/gettext )
+	doc? ( app-doc/doxygen )"
+
+REQUIRED_USE="?? ( dar32 dar64 )
+		gpg? ( gcrypt )"
+
+DOCS="AUTHORS ChangeLog NEWS README THANKS TODO"
+
+#PATCHES=(
+#)
+
+src_configure() {
+	local myconf=( --disable-upx )
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	# configure.ac is totally funked up regarding the AC_ARG_ENABLE
+	# logic.
+	# For example "--enable-dar-static" causes configure to DISABLE
+	# static builds of dar.
+	# Do _not_ use $(use_enable) until you have verified that the
+	# logic has been fixed by upstream.
+	use xattr || myconf+=( --disable-ea-support )
+	use dar32 && myconf+=( --enable-mode=32 )
+	use dar64 && myconf+=( --enable-mode=64 )
+	use doc || myconf+=( --disable-build-html )
+	# use examples && myconf+=( --enable-examples )
+	use gcrypt || myconf+=( --disable-libgcrypt-linking )
+	use gpg || myconf+=( --disable-gpgme-linking )
+	use lzo || myconf+=( --disable-liblzo2-linking )
+	use nls || myconf+=( --disable-nls )
+	if ! use static ; then
+		myconf+=( --disable-dar-static )
+		if ! use static-libs ; then
+			myconf+=( --disable-static )
+		fi
+	fi
+
+	econf ${myconf[@]}
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	einstalldocs
+
+	if ! use static-libs ; then
+		prune_libtool_files --all
+	fi
+}