sys-kernel/gentoo-kernel-bin: add 5.4.148-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index eb85293378e0..fbb4f0572550 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -121,6 +121,7 @@ DIST gentoo-kernel-5.4.147-1.amd64.xpak 61347875 BLAKE2B 41b273a3ea9af3606042d11
 DIST gentoo-kernel-5.4.147-1.arm64-r1.xpak 57992645 BLAKE2B 2082ba9faf0b111ad75875e09d2777a9a246077446d5e585155406fe5712883a90b625dbd3b09d6c80a5f51f0dd0d9d6baae3120ab03cdf082f77f01da3c2c57 SHA512 449192602073260e19f9c5b7bb31e959607e0b96876e63a1e75e4e9a79e435cb00b7ff57e1c4b297283ec6b07d407013f83f771894ff80df4f29c3f7c257bf1a
 DIST gentoo-kernel-5.4.147-1.x86.xpak 53170376 BLAKE2B 26c845e525c9cac5f31dd1e8cd19407cd367af395f2c2d34bd240c166d457fd3cbc86f9dfe3f10b9379110fd8c842edf6746345d3ff83ccb861c921aa1980ff4 SHA512 ec74127841f6adc7be48376d20365070ed3c4ebde3b9f2c2f5be8107f16665ddab1e88319448ae6a059e1f29eb0e7349a2b4b01111dea60d9052d2e8fb233342
 DIST gentoo-kernel-5.4.148-1.amd64.xpak 61364378 BLAKE2B 2d5a665f5ccee0de5abc78d593b8bc6f1da0fa6fa9573ee9c0a65efaae9629ac3ea0b26a4b83e6abb23eee5fcb842fd67a395af35fb5476529b30dc0739d7944 SHA512 277064e06bdf25fc67f0894ab1d8116f23c71488b92a1751833c6aff684c7f2d28e2116e31d40878caa3f741fe9fe61f1f0c3cfaca4677298d2851b22afdf1ff
+DIST gentoo-kernel-5.4.148-1.arm64-r1.xpak 57998682 BLAKE2B a27bee25e2e6b2c0fea38cb5bee1ce433c6dbf10468b374ffb237a15403a4acb7feb0729526d337c5c9b1a85c4afc63716fa3c4b5fbe32c03ddb6966765f8946 SHA512 c72a4d8bc4bca7cf9ad5b594d7cadff11f9a4ec7181c0dbdce14919a1af50c1a901dd69b1a5d3f35abe51f9ca82f729f352ac8873d0b0f225e4bdd45a213b350
 DIST gentoo-kernel-5.4.148-1.x86.xpak 53159913 BLAKE2B 7269d52529bf78b43819ffaf435d129ad6982f8046239a15da5c6df359feada8793fed93b206e3aa031817fbb235d221d7468601f7091f40cf5bdd16c30100c9 SHA512 07c4e3b73122ac915695858891fb408ed17ba11ed8e6adf1e17b8eda6ec4112ef293db5154067dfbfd8d32ec6b1380797f87263272c1b16b6d1044476e054a05
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.148-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.148-r1.ebuild
new file mode 100644
index 000000000000..3b97f74d1041
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.148-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64-r1.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}