media-sound/cantata: 2.4.1 version bump

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 120 insertions, 0 deletions

diff --git a/media-sound/cantata/Manifest b/media-sound/cantata/Manifest
index a36a1c3c6c03..dbc8d81d7963 100644
--- a/media-sound/cantata/Manifest
+++ b/media-sound/cantata/Manifest
@@ -1 +1,2 @@
 DIST cantata-2.3.3.tar.bz2 2445139 BLAKE2B 679ac68afa6219aa684aed1202bb2268552f6fe560db36e17748b9b220ae6ec4ef103ff68b3bcc7127835f8a2debd32895f5edf319a759ce78bc161c4e540a84 SHA512 8314930c9e16a5811f607f131ce7134daa0c6de81c5f87d45967c076895540b388b89b3f2cbd82950f6defb1087e61923c1719670f19b4ed3c074f05fe8577c6
+DIST cantata-2.4.1.tar.bz2 2550982 BLAKE2B 1d965ce4a5a73d4695b51def9753c95376b71367f2e6abf69681aad84e387d86d87abcf623f613a517e5e08a633e4e9bf2bae2d28858535fac2f05ade73a6c01 SHA512 9bb9953f41ad562e186c201505db6ea42dccdcb0b60e0c6eda0c5521428ecafdba95b51e8827de3498b2b25284d36f800bfa96a49839d2a69e0f92705f44a439
diff --git a/media-sound/cantata/cantata-2.4.1.ebuild b/media-sound/cantata/cantata-2.4.1.ebuild
new file mode 100644
index 000000000000..3a8db8b4bd5a
--- /dev/null
+++ b/media-sound/cantata/cantata-2.4.1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="cs da de en_GB es fr hu it ja ko pl pt_BR ru zh_CN"
+inherit cmake l10n qmake-utils xdg
+
+DESCRIPTION="Featureful and configurable Qt client for the music player daemon (MPD)"
+HOMEPAGE="https://github.com/CDrummond/cantata"
+SRC_URI="https://github.com/CDrummond/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="cdda cddb cdio http-server libav mtp musicbrainz replaygain streaming taglib udisks zeroconf"
+REQUIRED_USE="
+	?? ( cdda cdio )
+	cdda? ( udisks || ( cddb musicbrainz ) )
+	cddb? ( || ( cdio cdda ) taglib )
+	cdio? ( udisks || ( cddb musicbrainz ) )
+	mtp? ( taglib udisks )
+	musicbrainz? ( || ( cdio cdda ) taglib )
+	replaygain? ( taglib )
+"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/zlib
+	virtual/libudev:=
+	cdda? ( media-sound/cdparanoia )
+	cddb? ( media-libs/libcddb )
+	cdio? ( dev-libs/libcdio-paranoia )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5= )
+	replaygain? (
+		media-libs/libebur128
+		media-sound/mpg123
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	streaming? ( dev-qt/qtmultimedia:5 )
+	taglib? (
+		media-libs/taglib[asf(+),mp4(+)]
+		udisks? ( sys-fs/udisks:2 )
+	)
+	zeroconf? ( net-dns/avahi )
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-lang/perl[ithreads]
+	|| ( kde-frameworks/breeze-icons:5 kde-frameworks/oxygen-icons:* )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtconcurrent:5
+"
+
+# cantata has no tests
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}/${PN}-2.2.0-headers.patch" )
+
+src_prepare() {
+	remove_locale() {
+		rm "translations/${PN}_${1}".ts || die
+	}
+
+	cmake_src_prepare
+
+	# Unbundle 3rd party libs
+	rm -r 3rdparty/{ebur128,qtsingleapplication} || die
+
+	l10n_find_plocales_changes "translations" "${PN}_" ".ts"
+	l10n_for_each_disabled_locale_do remove_locale
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCANTATA_HELPERS_LIB_DIR="$(get_libdir)"
+		-DENABLE_CDPARANOIA=$(usex cdda)
+		-DENABLE_CDDB=$(usex cddb)
+		-DENABLE_CDIOPARANOIA=$(usex cdio)
+		-DENABLE_HTTP_SERVER=$(usex http-server)
+		-DENABLE_MTP=$(usex mtp)
+		-DENABLE_MUSICBRAINZ=$(usex musicbrainz)
+		-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
+		-DENABLE_FFMPEG=$(usex replaygain)
+		-DENABLE_MPG123=$(usex replaygain)
+		-DENABLE_HTTP_STREAM_PLAYBACK=$(usex streaming)
+		-DENABLE_TAGLIB=$(usex taglib)
+		-DENABLE_DEVICES_SUPPORT=$(usex udisks)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_REMOTE_DEVICES=OFF
+		-DENABLE_UDISKS2=ON
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	has_version media-sound/mpd || \
+		elog "An instance of media-sound/mpd, local or remote, is required to set up Cantata."
+
+	if ! has_version app-misc/media-player-info; then
+		elog "Install app-misc/media-player-info to enable identification"
+		elog "and querying of portable media players"
+	fi
+}