dev-java/jempbox: jdk and eapi upgrade

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/dev-java/jempbox/jempbox-1.7.1-r1.ebuild b/dev-java/jempbox/jempbox-1.7.1-r1.ebuild
new file mode 100644
index 000000000000..74126da57f9a
--- /dev/null
+++ b/dev-java/jempbox/jempbox-1.7.1-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2
+
+MY_PN=pdfbox
+
+DESCRIPTION="An open source Java library for parsing font files"
+HOMEPAGE="https://pdfbox.apache.org/"
+SRC_URI="mirror://apache/${MY_PN}/${PV}/${MY_PN}-${PV}-src.zip"
+
+LICENSE="BSD"
+SLOT="1.7"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=virtual/jre-1.8"
+DEPEND="
+	>=virtual/jdk-1.8
+	app-arch/unzip
+	test? ( dev-java/ant-junit:0 )"
+
+S="${WORKDIR}/${MY_PN}-${PV}/${PN}"
+
+src_prepare() {
+	default
+
+	cp -v "${FILESDIR}"/${P}_maven-build.xml build.xml || die
+}
+
+JAVA_ANT_REWRITE_CLASSPATH="yes"
+
+src_test() {
+	java-pkg-2_src_test
+}
+
+src_install() {
+	java-pkg_newjar target/${P}.jar ${PN}.jar
+
+	use doc && java-pkg_dojavadoc target/site/apidocs
+	use source && java-pkg_dosrc src/main/java/org
+}
diff --git a/dev-java/jempbox/jempbox-1.8.11-r1.ebuild b/dev-java/jempbox/jempbox-1.8.11-r1.ebuild
new file mode 100644
index 000000000000..65c154444a2f
--- /dev/null
+++ b/dev-java/jempbox/jempbox-1.8.11-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="pdfbox"
+MY_P="${MY_PN}-${PV}"
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="An open source Java library for working with XMP metadata"
+HOMEPAGE="https://pdfbox.apache.org/"
+SRC_URI="mirror://apache/${MY_PN}/${PV}/${MY_P}-src.zip"
+LICENSE="Apache-2.0"
+SLOT="1.8"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="test"
+
+RDEPEND=">=virtual/jre-1.8"
+
+DEPEND=">=virtual/jdk-1.8
+	app-arch/unzip
+	test? ( dev-java/junit:4 )"
+
+S="${WORKDIR}/${MY_P}/${PN}"
+JAVA_SRC_DIR="src/main/java"
+
+src_install() {
+	java-pkg-simple_src_install
+	dodoc README.txt
+}
+
+src_test() {
+	local DIR=src/test/java
+	local CP="${DIR}:${PN}.jar:$(java-pkg_getjars junit-4)"
+	local TESTS=$(find ${DIR} -name "*Test.java")
+	TESTS="${TESTS//src\/test\/java\/}"
+	TESTS="${TESTS//.java}"
+	TESTS="${TESTS//\//.}"
+
+	ejavac -cp "${CP}" -d ${DIR} $(find ${DIR} -name "*.java")
+	ejunit4 -classpath "${CP}" ${TESTS}
+}