sci-libs/ViSP: bump to 3.0.1

Package-Manager: Portage-2.3.3, Repoman-2.3.1

3 files changed, 120 insertions, 0 deletions

diff --git a/sci-libs/ViSP/Manifest b/sci-libs/ViSP/Manifest
index 317397c04871..65d567697961 100644
--- a/sci-libs/ViSP/Manifest
+++ b/sci-libs/ViSP/Manifest
@@ -1 +1,2 @@
 DIST visp-3.0.0.tar.gz 22938301 SHA256 cac5c79b00ca9bc2eeaeacffdc6e3c6f88ee101ec16f729ad3058d37092bf05f SHA512 4ba522731ffbbb55082dc9e0cfecb6bd42ad0abff88d95bd7d33f233a9159139ddef032e087a03b261c8ee2d6bc0cf4807819a27fae11ea91ec0482038acecdc WHIRLPOOL ded182caea33af0393e2e545808f03626aaf9a5929a11781953518722a5b8fbeca9d24dafd55d789ab9a71c6005eb0491c80d76285434c61f7d67f9fac9751ed
+DIST visp-3.0.1.tar.gz 26029005 SHA256 8aefd21f30dd4f6d210c59c28704f9e3adf874e3337571a3ae65a65946c94326 SHA512 558e9acbd7ac5ef2193dca026062b75e0a30a7efbcae7d1e7d392b0855e643ee96ab9f60c19465f6bfa861374e30d9e91faf2f860e0442fa48ea5ea384b4e3fa WHIRLPOOL ae3bbdbf580826fe392d372014d1e53db0bbdf53bdc4d2a631a2fa53b4991bc8f715eb428e1f8ba3c44574b5e81d2b3893da1b6bfc2084e538d656d073955348
diff --git a/sci-libs/ViSP/ViSP-3.0.1.ebuild b/sci-libs/ViSP/ViSP-3.0.1.ebuild
new file mode 100644
index 000000000000..deb111f72890
--- /dev/null
+++ b/sci-libs/ViSP/ViSP-3.0.1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="Visual Servoing Platform: visual tracking and visual servoing library"
+HOMEPAGE="http://www.irisa.fr/lagadic/visp/visp.html"
+SRC_URI="http://gforge.inria.fr/frs/download.php/latestfile/475/visp-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm"
+IUSE="
+	+coin demos +dmtx doc examples ffmpeg gsl ieee1394 jpeg lapack motif ogre
+	ois opencv png qt4 test tutorials usb v4l X xml +zbar zlib
+	cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3
+"
+
+RDEPEND="
+	coin? ( media-libs/coin virtual/opengl )
+	dmtx? ( media-libs/libdmtx )
+	ffmpeg? ( virtual/ffmpeg )
+	gsl? ( sci-libs/gsl )
+	ieee1394? ( media-libs/libdc1394 )
+	jpeg? ( virtual/jpeg:0 )
+	lapack? ( virtual/lapack )
+	!qt4? ( motif? ( media-libs/SoXt ) )
+	ogre? ( dev-games/ogre[ois?] dev-libs/boost:=[threads] )
+	opencv? ( media-libs/opencv qt4? ( media-libs/opencv[-qt5(-)] ) )
+	png? ( media-libs/libpng:0= )
+	qt4? ( media-libs/SoQt dev-qt/qtgui:4 )
+	usb? ( virtual/libusb:1 )
+	v4l? ( media-libs/libv4l )
+	X? ( x11-libs/libX11 )
+	xml? ( dev-libs/libxml2 )
+	zbar? ( media-gfx/zbar )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen virtual/latex-base media-gfx/graphviz )
+	virtual/pkgconfig
+	test? ( sci-misc/ViSP-images )
+	v4l? ( virtual/os-headers )"
+RDEPEND="${RDEPEND}
+	demos? ( sci-misc/ViSP-images )"
+REQUIRED_USE="
+	ffmpeg? ( opencv )
+	ois? ( ogre )
+	qt4? ( coin )
+	motif? ( coin )
+"
+
+S="${WORKDIR}/visp-${PV}"
+PATCHES=( "${FILESDIR}/${PN}-3.0.1-opencv.patch" "${FILESDIR}/${PN}-3.0.0-ffmpeg3.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		"-DBUILD_EXAMPLES=$(usex examples ON OFF)"
+		"-DBUILD_TESTS=$(usex test ON OFF)"
+		"-DBUILD_DEMOS=$(usex demos ON OFF)"
+		"-DBUILD_TUTORIALS=$(usex tutorials ON OFF)"
+		"-DUSE_COIN3D=$(usex coin ON OFF)"
+		"-DUSE_DC1394=$(usex ieee1394 ON OFF)"
+		"-DUSE_DMTX=$(usex dmtx ON OFF)"
+		"-DUSE_FFMPEG=$(usex ffmpeg ON OFF)"
+		"-DUSE_GSL=$(usex gsl ON OFF)"
+		"-DUSE_LAPACK=$(usex lapack ON OFF)"
+		"-DUSE_JPEG=$(usex jpeg ON OFF)"
+		"-DUSE_PNG=$(usex png ON OFF)"
+		"-DUSE_LIBUSB_1=$(usex usb ON OFF)"
+		"-DUSE_OGRE=$(usex ogre ON OFF)"
+		"-DUSE_OIS=$(usex ois ON OFF)"
+		"-DUSE_OPENCV=$(usex opencv ON OFF)"
+		"-DUSE_SOQT=$(usex qt4 ON OFF)"
+		"-DUSE_SOXT=$(usex motif "$(usex qt4 OFF ON)" OFF)"
+		"-DUSE_V4L2=$(usex v4l ON OFF)"
+		"-DUSE_X11=$(usex X ON OFF)"
+		"-DUSE_XML2=$(usex xml ON OFF)"
+		"-DUSE_ZBAR=$(usex zbar ON OFF)"
+		"-DUSE_ZLIB=$(usex zlib ON OFF)"
+		"-DCOIN3D_INCLUDE_DIR=${EPREFIX:-${SYSROOT}}/usr/include/coin"
+		"-DSOQT_INCLUDE_DIR=${EPREFIX:-${SYSROOT}}/usr/include/coin"
+		"-DENABLE_SSE2=$(usex cpu_flags_x86_sse2 ON OFF)"
+		"-DENABLE_SSE3=$(usex cpu_flags_x86_sse3 ON OFF)"
+		"-DENABLE_SSSE3=$(usex cpu_flags_x86_ssse3 ON OFF)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	cd "${BUILD_DIR}"
+	use doc && emake visp_doc
+}
+
+src_install() {
+	cmake-utils_src_install
+	if use tutorials ; then
+		dodoc -r tutorial
+		docompress -x /usr/share/doc/${PF}/tutorial
+	fi
+	cd "${BUILD_DIR}"
+	use doc && dohtml -r doc/html/*
+}
diff --git a/sci-libs/ViSP/files/ViSP-3.0.1-opencv.patch b/sci-libs/ViSP/files/ViSP-3.0.1-opencv.patch
new file mode 100644
index 000000000000..c50dcb6d182e
--- /dev/null
+++ b/sci-libs/ViSP/files/ViSP-3.0.1-opencv.patch
@@ -0,0 +1,12 @@
+Index: visp-3.0.1/modules/core/CMakeLists.txt
+===================================================================
+--- visp-3.0.1.orig/modules/core/CMakeLists.txt
++++ visp-3.0.1/modules/core/CMakeLists.txt
+@@ -182,6 +182,7 @@ if(USE_OPENCV)
+   if(OpenCV_INCLUDE_DIRS)
+     list(APPEND opt_incs ${OpenCV_INCLUDE_DIRS})
+   endif()
++  list(APPEND opt_libs ${OpenCV_LIBS})
+ endif(USE_OPENCV)
+ 
+ if(USE_YARP)